a function return 2 values

[Silvio.Falconi]

I have a function and I wish have the value of return and another value it is possible ?
sample :

If !GIORNOLIB(nGiorno, @nOre, nOra)


How i can have also nOre ?
to use then to another function sample
IF calsslib(ngiorno,nore,nora)


...

the function I found on old clipper app I must converte

static function GIORNOLIB(nGiorno, nOre, nOra)
Local lreturn := .f.

if (Val(do->giornoli) == nGiorno .AND. nOra == 1 .AND. ;
do->punti < "3" .AND. Val(do->giornoli) == nGiorno ;
.AND. nOra == 2 .AND. do->punti < "2")

nOre:= iif(Left(da->parame, 1) == "0", 10, Val(Left(da->parame, 1)))

lreturn := .T.
endif
return lreturn

[ukoenig]

Silvio,

a RETURN with many values
a INI-sample :

Code: Select all  Expand view  RUN

// the INI returns a ARRAY
aValues := GET_INI(cWorkFile, nTxtColor)

cWorkFile := aValues[1] // from INI
nTxtColor := aValues[2] // from INI
...
...
// --------- INI - Read -------------

FUNCTION GET_INI( cWorkFile, nTxtColor )
Local oIni, cIniFile := c_path + "PROJECT.INI"

IF !FILE ( c_path + "PROJECT.ini" ) // creates the INI if not exists
    SAVE_INI( cWorkFile, nTxtColor )
ELSE
    INI oIni FILE c_path + "PROJECT.INI"
                 cWorkFile := GetPvProfString( "System",            "Image",        "Picture1.jpg" , cIniFile )
             nTxtColor :=  Val(GetPvProfString( "System",       "Textcolor",    "0" , cIniFile ) )
    ENDINI
ENDIF

RETURN { cWorkFile, nTxtColor } // return-values = ARRAY
 

best regards
Uwe

[James Bott]

1) As Uwe said, return an array

2) And my preferred method, use a class with two data objects.

Code: Select all  Expand view  RUN

class TWhatever
   Data value1
   Data value2
endclass

Method new(...)
   ::value1:=1
   ::value2:=2
return self

oObj:=TWhatver():new()

msgInfo( oObj:value1 )
msgInfo( oObj:value2 )

 

3) If the calling program is in the same prg as the function you could use file-wide static vars

I highly recommend number 2, the class method.

James

[Daniel Garcia-Gil]

Hello

I prefer use hash, example

h = any()

You can access h[ "var1" ], h[ "var2" ]

Functions any()

Local hVar = {=>}

...

hVar [ "var1" ] = 1234
hVar [ "var2" ] = "abcd"

Return hVar

[James Bott]

Daniel,

I don't really understand how that works. Can you provide a complete working example?

James

[Enrico Maria Giordano]

James,

here it is:

Code: Select all  Expand view  RUN

FUNCTION MAIN()

    LOCAL hHash := MyFunc()

    ? hHash[ "Val1" ], hHash[ "Val2" ]

    RETURN NIL


STATIC FUNCTION MYFUNC()

    LOCAL hHash := { => }

    hHash[ "Val1" ] = 123
    hHash[ "Val2" ] = 456

    RETURN hHash

EMG

[James Bott]

Thanks Enrico.

I am getting the feeling that is how classes work behind the scenes?

James

[Enrico Maria Giordano]

James,

Thanks Enrico.

I am getting the feeling that is how classes work behind the scenes?

Probably that's the concept. But hashes are implemented at C language level in xHarbour, not at PRG one.

EMG

[Silvio.Falconi]

thanks to all
but On old clipper app I have this command

If Giornolib(ngiorno,@nOre,nOra)

then the value of @nOre id used by another function


the Giornolib function is :

static function GIORNOLIB(ngiorno, nOre, nOra)
if (Val(anagrafe->giornoli) == ngiorno .AND. nOra == 1 .AND. ;
anagrafe->punti < "3" .AND. Val(anagrafe->giornoli) == ngiorno ;
.AND. nOra == 2 .AND. anagrafe->punti < "2")
nOre:= iif(Left(datis->parame, 1) == "0", 10, ;
Val(Left(datis->parame, 1)))
return .F.
endif
return .T.


I not Know what I made on 1992 but the app on Dos run ok

[Enrico Maria Giordano]

Silvio,

@ as parameter suffix means "by reference". [x]Harbour fully support it, just like Clipper.

EMG

[Marc Vanzegbroeck]

thanks to all
but On old clipper app I have this command

If Giornolib(ngiorno,@nOre,nOra)

then the value of @nOre id used by another function


the Giornolib function is :

static function GIORNOLIB(ngiorno, nOre, nOra)
if (Val(anagrafe->giornoli) == ngiorno .AND. nOra == 1 .AND. ;
anagrafe->punti < "3" .AND. Val(anagrafe->giornoli) == ngiorno ;
.AND. nOra == 2 .AND. anagrafe->punti < "2")
nOre:= iif(Left(datis->parame, 1) == "0", 10, ;
Val(Left(datis->parame, 1)))
return .F.
endif
return .T.


I not Know what I made on 1992 but the app on Dos run ok

Silvio,

That is also working in FWH

[mercurial]

Hi

Functions can return only one value. This value can be of any supported type so you can simulate multiple return values using array, hashes, classes.

Or you can use parameters passed by reference:

If Giornolib(ngiorno,@nOre,nOra)

In this call nGiorno and nOra is passed by value (the actual values of nGiorno and nOra are passed to the function) while nOre is passed by reference (the "address" of the variable is passed to the function).

Infact in the function GiornoLib( nGiorno, nOre, nOra ) // Note that in function definition you can't specify @
there is this instruction:
nOre:= iif(Left(datis->parame, 1) == "0", 10, Val(Left(datis->parame, 1)))

A new value to variable nOre is assigned: you can check that after the IF the variable has changed its value.

So your question "How i can have also nOre ?" is easily answered: you already have nOre "returned"... actually assigned and not returned...

PS: note that boolean, date, chars, numerics are always passed by value (unless @ is specified). "Complex" objects like classes, arrays, hashes etc are always passed by reference (you can modify them in the function)
PPS: the fact that the variable names in GiornoLib are the same as in the calling ones is casual...