How to create a PRIVATE variable owned by the caller?

[Enrico Maria Giordano]

This is a not working sample. Any ideas?

Code: Select all | Expand

#include "Fivewin.ch"


FUNCTION MAIN()

    CREATEVAR( "TEST", "Hello" )

    ? M -> TEST // it does not exist here

    RETURN NIL


STATIC FUNCTION CREATEVAR( cName, xValue )

    // How to create a PRIVATE variable owned by the caller?

    __MVPRIVATE( cName )

    __MVPUT( cName, xValue )

    ? M -> TEST

    RETURN NIL

[hmpaquito]

Hola,

Por definicion una variable PRIVATE tiene ambito en la funcion que la crea y en las funciones que son llamadas por la funcion que la crea.

En el caso que vd. expone es normal que no funcione.

Use en su caso PUBLIC

Salu2

[Enrico Maria Giordano]

No, it is possible. Please look at RESTORE FROM command.

[hmpaquito]

PRIVATE
Create and initialize private memory variables and arrays

Syntax

PRIVATE <identifier> [[:= <initializer>], ... ]

Arguments

<identifier> is the name of a private variable or array to create.
If the <identifier> is followed by square brackets ([ ]), an array is
created and assigned to the <identifier>. When the <identifier>
specification indicates an array, the syntax for specifying the number
of elements for each dimension can be array[<nElements>,
<nElements2>,...] or array[<nElements>][<nElements2>]... The maximum
number of elements per dimension is 4096. The maximum number of
dimensions is limited only by available memory.

<initializer> is the optional assignment of a value to a new private
variable. An array cannot be given values with an <initializer>. An
<initializer> for a private variable consists of the inline assignment
operator (:=) followed by any valid CA-Clipper expression including a
literal array. If no explicit <initializer> is specified, the variable
is initialized to NIL. In the case of an array, each element is
initialized to NIL.

You can create and, optionally, initialize a list of variables and
arrays with one PRIVATE statement if the definitions are separated by
commas.

Description

The PRIVATE statement creates variables and arrays visible within the
current and invoked procedures or user-defined functions. This class of
variable is said to have dynamic scope. Private variables exist for the
duration of the active procedure or until explicitly released with CLEAR
ALL, CLEAR MEMORY, or RELEASE. When a private variable or array is
created, existing and visible private and public variables of the same
name are hidden until the current procedure or user-defined function
terminates.

[karinha]

Harbour only?

https://vivaclipper.wordpress.com/2014/01/23/__mvget/

https://vivaclipper.wordpress.com/2014/ ... mvarblock/

https://hmgforum.com/esgici/vivaclipper ... index.html

https://harbour.github.io/doc/harbour.html#__mvprivate

https://harbour.github.io/doc/harbour.html#__mvput

Regards, saludos.

[Enrico Maria Giordano]

Please look at this sample:

Code: Select all | Expand

#include "Fivewin.ch"


FUNCTION MAIN()

    CREATEMEM( "MYTEST.MEM", "TEST", "Hello" )

//    ? M -> TEST // it does not exist here

    __MVRESTORE( "MYTEST.MEM", .T. )

    ? M -> TEST // now it exists

    RETURN NIL


STATIC FUNCTION CREATEMEM( cMem, cVar, xVal )

    PRIVATE &cVar := xVal

    SAVE TO ( cMem )

    RETURN NIL

[hmpaquito]

CreateMem() is not neccesary for private declaration on top main function:

Code: Select all | Expand

#include "Fivewin.ch"


FUNCTION MAIN()

// Note !!!!!! Try without that function call
/*    CREATEMEM( "MYTEST.MEM", "TEST", "Hello" )  
*/

//    ? M -> TEST // it does not exist here
    
    // Here implicit PUBLIC vars declaration
    __MVRESTORE( "MYTEST.MEM", .T. )

    ? M -> TEST // now it exists

    RETURN NIL


STATIC FUNCTION CREATEMEM( cMem, cVar, xVal )

    PRIVATE &cVar := xVal

    SAVE TO ( cMem )

    RETURN NIL

[Enrico Maria Giordano]

Code: Select all | Expand

Error description: (DOS Error 2) BASE/2005  Open error: MYTEST.MEM

[hmpaquito]

Try it with your mytest.mem

[Enrico Maria Giordano]

You completely missed the point.

[Antonio Linares]

Dear Enrico,

Code: Select all | Expand

#include "Fivewin.ch"

FUNCTION MAIN()

    CREATEVAR( "TEST", "Hello" )

    ? M -> TEST // it exists here

    RETURN NIL


STATIC FUNCTION CREATEVAR( cName, xValue )

    __MVPRIVATE( cName )
    __MVPUT( cName, xValue )
    __MVSETBASE()

    ? M -> TEST

    RETURN NIL
 

[Enrico Maria Giordano]

Great! Is there a similar function (__MVSETBASE()) available for xHarbour?

[Antonio Linares]

I am afraid no as xHarbour does not have the member stackstate in the struct hb_struSymbol

Maybe there is another way to do it, but I don't know it

[Enrico Maria Giordano]

Ok, no problem, thank you.

[karinha]

C:\HBBCC74\src\vm

03/04/2020 19:58 52.717 memvars.c

Regards, saludos.