FiveTech Software tech support forums

www.FiveTechSoft.com
https://fivetechsupport.com/forums/

Seek en XBrowse con Dolphin texto con Ñ

https://fivetechsupport.com/forums/viewtopic.php?t=32821

Page 2 of 4

Re: Seek en XBrowse con Dolphin texto con Ñ

Posted: Thu Aug 18, 2016 8:16 pm
by cmsoft
Si, solo con Dolphin
Probe este ejemplo que me paso Mr Rao: (Adaptado para mis tablas) y funciona bien con FWMYSQL y con ARRAY. No con Dolphin

Code: Select all | Expand

#include "fivewin.ch"
#include "tdolphin.ch"

REQUEST HB_LANG_ES
REQUEST HB_CODEPAGE_ESWIN

static oCn, oServer
static cHost := "xxx", cUser := "xxx", cPwd := "xxx", cDB := "xxx"
static cCollate   := "utf8_spanish2_ci"

//----------------------------------------------------------------------------//

function Main()

   HB_CDPSELECT("ESWIN")
   HB_LangSelect( "ES_ES" )

   FWMYSQL_test()
   Dolphin_test()

return nil

//----------------------------------------------------------------------------//

function FWMYSQL_test()

   local oRs
   FWCONNECT oCn HOST cHost USER cUser PASSWORD cPwd DATABASE cDB
   oRs   := oCn:RowSet( "test" )
   oRs:Sort := "nombre"  //Ordenado por nombre
   oRs:GoTop()

   xbrowser oRs TITLE "FWH " + cCollate AUTOSORT

return nil

//----------------------------------------------------------------------------//

function Dolphin_test()

   local oQry, aTabla := {}

   CONNECT oServer HOST cHost USER cUser PASSWORD cPwd DATABASE cDB

   oQry  := oServer:Query( "select * from test order by nombre" )
   XBROWSER oQry TITLE "Dolphin " + cCollate AUTOSORT

   oQry:GoTop()
   do while !oQry:Eof()
      AADD(aTabla,oQry:nombre)
      oQry:Skip()
   enddo
   
   XBROWSER aTabla TITLE "Array copiado de Dolphin " + cCollate AUTOSORT

return nil

Si no es mucho atrevimiento, puedo pasarte por mail el seteo de la base de datos que tengo colgada en un servidor y lo puedes ver.
Gracias por tu tiempo.

Re: Seek en XBrowse con Dolphin texto con Ñ

Posted: Thu Aug 18, 2016 10:22 pm
by MarioG
Gente:
Quizas no me exprese bien; pero yo, sin leer las particularidades de la collate, selccioné: latin1_spanish_ci. Y tanto el orden como la búsqueda resultan correctas
Uso TDophin, MariaDb y xBrowse

Re: Seek en XBrowse con Dolphin texto con Ñ

Posted: Thu Aug 18, 2016 10:48 pm
by cmsoft
Mario:
Algun seteo particular de lenguage? Ya que vos usas Tdolphin y Xbrowse y te funciona.
Le asigne a la tabla la collation que me indicas y sigue sin funcionar.
Yo tengo (como puse en el codigo)

HB_CDPSELECT("ESWIN")
HB_LangSelect( "ES_ES" )
No se si es de Dolphin pero tenia en algun momento Set_MyLang( "es_es" ), pero lo pongo y tampoco me funciona.

Re: Seek en XBrowse con Dolphin texto con Ñ

Posted: Thu Aug 18, 2016 11:44 pm
by MarioG
CM;
Mi seteo inicial es:

Code: Select all | Expand


REQUEST HB_Lang_ESWIN, HB_CODEPAGE_ESWIN // A decir verdad este lo tengo declarado con DBFs, y fue por "copiar y pegar"
...

INIT PROCEDURE Inicio()

   HB_LangSelect(  "ESWIN" )        // Al parecer ambos son distintos a los que vos declaras
   HB_SetCodePage( "ESWIN" )

   SET DATE TO BRITISH
   SET CENTURY ON
   SET EPOCH TO (Year( Date() )-99)
   Set(_SET_INSERT, .T.)
 

Re: Seek en XBrowse con Dolphin texto con Ñ

Posted: Fri Aug 19, 2016 12:43 am
by cmsoft
Mario:
Te envie un mail para que me hagas una prueba con mis datos.
Probé con tu seteo y tampoco anduvo
Muchas gracias por tu tiempo

Re: Seek en XBrowse con Dolphin texto con Ñ

Posted: Fri Aug 19, 2016 1:38 am
by nageswaragunupudi
You can send the data to me in dbf or excel format.

nageswaragunupudi@gmail.com

Re: Seek en XBrowse con Dolphin texto con Ñ

Posted: Fri Aug 19, 2016 2:23 am
by cmsoft
Mr Rao:
Gracias por su interes. Le envie un mail con los datos de conexion y otro con el archivo excel exportado de la tabla
Saludos

Re: Seek en XBrowse con Dolphin texto con Ñ

Posted: Fri Aug 19, 2016 3:11 am
by nageswaragunupudi
Thank you.
I tried this program with your database

Code: Select all | Expand

#include "fivewin.ch"

REQUEST HB_LANG_ES
REQUEST HB_CODEPAGE_ESWIN

static oCn
static cHost := "190.228.29.63", cUser := "gusano_admin", cPwd := "buitrox", cDB := "cgtest"

//----------------------------------------------------------------------------//

function Main()

   local oRs, cTable

   HB_CDPSELECT("ESWIN")
   HB_LangSelect( "ES_ES" )

   FWCONNECT oCn HOST cHost USER cUser PASSWORD cPwd DATABASE cDB

   if oCn == nil
      ? "Not connected"
      return nil
   endif

   XBROWSER oCn:ListTables() SELECT ( cTable := oBrw:aCols[ 1 ]:Value )

   oRs   := oCn:RowSet( cTable )

   XBROWSER oRs TITLE cTable AUTOSORT

   oCn:Close()

return nil

//----------------------------------------------------------------------------//
 


Image

I am using Spanish OS Keyboard downloaded.
Now that you have purchased FWH16.04, you better use FWRowSet. This works irrespective of the collation you used for the table.

Re: Seek en XBrowse con Dolphin texto con Ñ

Posted: Fri Aug 19, 2016 3:24 am
by nageswaragunupudi
In the earlier program, we used XBROWSER.
Now let us try with full xbrowse code.

Code: Select all | Expand

#include "fivewin.ch"

REQUEST HB_LANG_ES
REQUEST HB_CODEPAGE_ESWIN

static oCn
static cHost := "190.228.29.63", cUser := "gusano_admin", cPwd := "buitrox", cDB := "cgtest"

//----------------------------------------------------------------------------//

function Main()

   local oRs, cTable

   HB_CDPSELECT("ESWIN")
   HB_LangSelect( "ES_ES" )

   FWCONNECT oCn HOST cHost USER cUser PASSWORD cPwd DATABASE cDB

   if oCn == nil
      ? "Not connected"
      return nil
   endif

   XBROWSER oCn:ListTables() SELECT ( cTable := oBrw:aCols[ 1 ]:Value )

   oRs   := oCn:RowSet( cTable )

//   XBROWSER oRs TITLE cTable AUTOSORT

   BrowseTable( cTable )

   oCn:Close()

return nil

//----------------------------------------------------------------------------//

static function BrowseTable( cTable )

   local oRs, oDlg, oFont, oBrw

   oRs      := oCn:RowSet( cTable )
   oRs:Sort := "nombre"
   oRs:GoTop()

   DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
   DEFINE DIALOG oDlg SIZE 700,400 PIXEL TRUEPIXEL FONT oFont

   @ 60,20 XBROWSE oBrw SIZE -20,-20 PIXEL OF oDlg ;
      DATASOURCE oRs AUTOCOLS AUTOSORT CELL LINES NOBORDER

   oBrw:CreateFromCode()

   @ 20,20 SAY oBrw:oSeek VAR oBrw:cSeek SIZE 200,24 PIXEL OF oDlg ;
      COLOR CLR_HRED,CLR_YELLOW

   ACTIVATE DIALOG oDlg CENTERED
   RELEASE FONT oFont

return nil

//----------------------------------------------------------------------------//
 


Image

Re: Seek en XBrowse con Dolphin texto con Ñ

Posted: Fri Aug 19, 2016 3:30 am
by cmsoft
Estimado Mr Rao, en ambos caso ud esta usando FWMYSQL, yo uso Dolphin. Con Dolphin tengo problemas. Con ARRAY y con FWMYSQL funciona bien.

Re: Seek en XBrowse con Dolphin texto con Ñ

Posted: Fri Aug 19, 2016 3:33 am
by cmsoft
Puede proba este codigo:

Code: Select all | Expand

#include "fivewin.ch"
#include "tdolphin.ch"

REQUEST HB_LANG_ES
REQUEST HB_CODEPAGE_ESWIN

static oCn, oServer
static cHost := "190.228.29.63", cUser := "gusano_admin", cPwd := "buitrox", cDB := "cgtest"
static cCollate   := "utf8_spanish2_ci"

//----------------------------------------------------------------------------//

function Main()

   HB_CDPSELECT("ESWIN")
   HB_LangSelect( "ES_ES" )
   
   FWMYSQL_test()
   Dolphin_test()

return nil

//----------------------------------------------------------------------------//

function FWMYSQL_test()

   local oRs
   local aData := { { "CAMISA" }, { "CAÑA" },  { "CANDADO" }, { "CANILLA" }, ;
                  { "CAÑO" }, { "CANOBOTE" } }

   FWCONNECT oCn HOST cHost USER cUser PASSWORD cPwd DATABASE cDB
/*
   if oCn:TableExists( "cana" )
      ocn:DropTable( "cana" )
   endif
   oCn:CreateTable( "cana", { { "name", 'C', 20, 0, cCollate } }, .t., cCollate )

   oCn:Insert( "cana", { "name" }, aData )
*/
   oRs   := oCn:RowSet( "test" )
   oRs:Sort := "nombre"   
   oRs:GoTop()

   xbrowser oRs TITLE "FWH " + cCollate AUTOSORT

return nil

//----------------------------------------------------------------------------//

function Dolphin_test()

   local oQry, aTabla := {}

   CONNECT oServer HOST cHost USER cUser PASSWORD cPwd DATABASE cDB

   oQry  := oServer:Query( "select * from test order by nombre" )
   XBROWSER oQry TITLE "Dolphin " + cCollate AUTOSORT

   oQry:GoTop()
   do while !oQry:Eof()
      AADD(aTabla,oQry:nombre)
      oQry:Skip()
   enddo
   
   XBROWSER aTabla TITLE "Array  " + cCollate AUTOSORT

return nil
 

Vera que en el caso de dolphin (segundo browse) la busqueda funciona mal.
Gracias

Re: Seek en XBrowse con Dolphin texto con Ñ

Posted: Fri Aug 19, 2016 4:29 am
by nageswaragunupudi
We shall try to find solution for Dolphin incremental seek.
Incidentally let me say Incremental Filter is working with Dolphin.
We shall get back to you again on incremental seek with Dolphin

Re: Seek en XBrowse con Dolphin texto con Ñ

Posted: Fri Aug 19, 2016 8:41 am
by cmsoft
Muchas gracias Mr. Rao!
Quedo a la espera de noticias suyas.
Por sierto, he verificado que si funciona el Filtro incremental, tanto con lWildSeek en .t. como en .f.
Saludos

Re: Seek en XBrowse con Dolphin texto con Ñ

Posted: Fri Aug 19, 2016 8:48 am
by cnavarro
Cesar, prueba asi
A mi me funciona, acabo de probarlo con tu base de datos

Code: Select all | Expand


   HB_CDPSELECT("ESWIN")
   HB_LangSelect( "ES" )
   
   Set_MyLang( "esp" )    // Añade esto

 

Re: Seek en XBrowse con Dolphin texto con Ñ

Posted: Fri Aug 19, 2016 8:52 am
by cmsoft
Perfecto Cristobal!!!!
Funciona Ok!!
Muchisimas gracias por tu tiempo!!
Saludos!!
All times are UTC
Page 2 of 4

Powered by phpBB® Forum Software © phpBB Limited