FiveTech Software tech support forums

www.FiveTechSoft.com

Skip to content

enviar emails desde fwh

Post a reply

Re: enviar emails desde fwh

Postby mmercado » Tue Feb 24, 2009 10:39 pm

FranciscoA wrote:He probado con el codigo que suministras (unicamente cambie los botones y omiti el attach), y da el siguiente error:
Hola Francisco:

Hice los cambios que mencionas a mi ejemplo y aquí funciona perfectamente con FWH 9.01 y también con FWH 8.02 (yo uso xHarbour).

Podrías poner aquí el programa como quedó después de tus cambios ?

También dime por favor la versión que usas de FWH y cual servidor de correo estás usando

Un abrazo.

Manuel Mercado
manuelmercado at prodigy dot net dot mx
User avatar
mmercado
 
Posts: 782
Joined: Wed Dec 19, 2007 7:50 am
Location: Salamanca, Gto., México
Top

Re: enviar emails desde fwh

Postby MANOLO » Tue Feb 24, 2009 10:44 pm

Hola carlos, el error que me da es en el :Send(), es como si no encontrara la funcion:

DATOS DEL ERROR CAUSADO POR LA APLICACIÓN
_________________________________________

Nombre del PC.........: PORTATIL
Tamaño del Ejecutable.: 5.491.712 bytes
Ruta, Nombre y Tipo...: Z:\datos\francew\FUENTES\factu32.Exe (32 bits)
Fecha y Hora del Error: 24/02/2009 - 11:42:02 p.m.
Tiempo desde el Inicio: 0 hours 0 mins 26 secs


DESCRIPCIÓN DEL ERROR PRODUCIDO
_______________________________

Error CDO.Message/3 DISP_E_MEMBERNOTFOUND: SEND
Argumentos:


LLAMADAS AL STACK
_________________

Llamado de TOLEAUTO:SEND(0)
Llamado de FSENDMAIL(4.360)
Llamado de CIERRA1(2.222)
Llamado de (b)REENVIA(2.173)
Llamado de TBUTTON:CLICK(0)
Llamado de TBUTTON:HANDLEEVENT(0)
Llamado de _FWH(0)
Llamado de SENDMESSAGE(0)
Llamado de TDIALOG:COMMAND(0)
Llamado de TWINDOW:HANDLEEVENT(0)
Llamado de TDIALOG:HANDLEEVENT(0)
Llamado de DIALOGBOX(0)
Llamado de TDIALOG:ACTIVATE(0)

Podrías ayudarme, gracias..
manolo
MANOLO
 
Posts: 87
Joined: Sun Oct 09, 2005 8:49 pm
Location: Spain
Top

Re: enviar emails desde fwh

Postby MANOLO » Tue Feb 24, 2009 10:50 pm

Se me olvidó poner el codigo:

Code: Select all  Expand view

#ifndef _CDOSYS_CH
#define _CDOSYS_CH
#define cdoSMTPServer       "http://schemas.microsoft.com/cdo/configuration/smtpserver"
#define cdoSMTPServerPort   "http://schemas.microsoft.com/cdo/configuration/smtpserverport"
#define cdoSendUsing        "http://schemas.microsoft.com/cdo/configuration/sendusing"
#define cdoSMTPPickupFolder "http://schemas.microsoft.com/cdo/configuration/smtpserverpickupdirectory"
#define cdoSMTPAuthenticate "http://schemas.microsoft.com/cdo/configuration/smtpauthenticate"
#define cdoSendUserName     "http://schemas.microsoft.com/cdo/configuration/sendusername"
#define cdoSendPassword     "http://schemas.microsoft.com/cdo/configuration/sendpassword"
#define cdoSMTPUseSSL       "http://schemas.microsoft.com/cdo/configuration/smtpusessl"
#define cdoSMTPConnectionTimeout "http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout"
#endif

Function fSendMail( cMailServer, cFrom, cTo, cSubject, cBody, cAttach, cBCC, cUser, cPass, nPort )

   Local oCfg, oMsg, oError, ;
         lAuth    := ! Empty( cUser ) .and. ! Empty( cPass ), ;
         nSendOpt := 2   // send using: 1 = pickup folder  2 = port  3 = remote mail server

   Default nPort    := 25, ;
           cSubject := "", ;
           cBody    := ""

   CursorWait()

   Try
      oCfg := CreateObject( "CDO.Configuration" )

      With Object oCfg:Fields
         :Item( cdoSMTPServer ):Value     := Trim( cMailServer )
         :Item( cdoSMTPServerPort ):Value := nPort
         :Item( cdoSendUsing ):Value      := nSendOpt
*         :Item( cdoSMTPConnectionTimeout):Value = 10 // intento hacer prueba con timeout para ver si es por eso.
         
         If lAuth
            :Item( cdoSMTPAuthenticate ):Value := .T.
            :Item( cdoSendUserName ):Value     := Trim( cUser )
            :Item( cdoSendPassword ):Value     := Trim( cPass )
            :Item( cdoSMTPUseSSL ):Value := .T.
           
           
         EndIf

         :Update()
      End With


      oMsg := CreateObject( "CDO.Message" )
       
      With Object oMsg
         :Configuration := oCfg
         :From          := Trim( cFrom )
         :To            := Trim( cTo )
         :Subject       := Trim( cSubject )
         :TextBody      := "Prueba de envio"
         :HTMLBody      := "<HTML>"+"<HEAD>"+"<BODY>"+"<b> This is the test HTML message body</b></br>"+"</BODY>"+"</HTML>" // prueba en html para ver si así funciona

        *:TextBody      := Trim( cBody )
     
         :Send()
         
      End With
       
       
       
   Catch oError
      CursorArrow()
      MsgStop( "No se pudo enviar el mensaje" + CRLF  + "Error: " + cValToChar( oError:GenCode) + CRLF + ;
               "SubC: " + cValToChar( oError:SubCode ) + CRLF + "OSCode: " + cValToChar( oError:OsCode ) + CRLF + ;
               "SubSystem: " + cValToChar( oError:SubSystem ) + CRLF + "Mensaje: " + oError:Description )

      oCfg := Nil
      oMsg := Nil
      Return Nil
   End Try
   

   
   oCfg := Nil
   oMsg := Nil
   SndPlaySound( GetWinDir() + "\media\Tada.wav", 0 )
   CursorArrow()

Return Nil

 
MANOLO
 
Posts: 87
Joined: Sun Oct 09, 2005 8:49 pm
Location: Spain
Top

Re: enviar emails desde fwh

Postby FranciscoA » Wed Feb 25, 2009 2:45 am

mmercado wrote:
FranciscoA wrote:He probado con el codigo que suministras (unicamente cambie los botones y omiti el attach), y da el siguiente error:
Hola Francisco:

Hice los cambios que mencionas a mi ejemplo y aquí funciona perfectamente con FWH 9.01 y también con FWH 8.02 (yo uso xHarbour).

Podrías poner aquí el programa como quedó después de tus cambios ?

También dime por favor la versión que usas de FWH y cual servidor de correo estás usando

Un abrazo.

Manuel Mercado


Hola Manuel. Muchas gracias por contestar. Así quedó el código:

//-------------------------------------------------------------------------

#include "FiveWin.ch"
**#include "TSButton.ch"
#include "CdoSys.ch"

#define WS_3DLOOK 4
#define CLR_HBROWN nRGB( 205, 192, 176 )
#define CLR_NBLUE nRGB( 142, 171, 194 )

//---------------------------------------------------------------------------------------------//

Function Main()

Local oDlg, aCtl[ 20 ], oFont

Local cMailServer := PadR( "smtp.hotmail.com", 60 ), ; // servidor de correo
cFrom := PadR( "remitente@hotmail.com", 60 ), ; // remitente
cTo := PadR( "destinatarios@hotmail.com", 180 ), ; // destinatario (uno o varios separados con comas)
cBCC := PadR( "destinatarios@hotmail.com", 180 ), ; // copias ocultas a (uno o varios separados con comas)
cAttach := PadR( "c:\fwh\bitmaps\fivewin.bmp", 180 ), ;// archivo anexo (uno o varios separados con comas)
cSubject := Space( 60 ), ; // asunto
cBody := Space( 500 ), ; // cuerpo del mensaje
nPort := 25, ; // puerto usado por el servidor de correo
cUser := Space( 60 ), ; // nombre de usuario para autenticación
cPass := Space( 30 ) // contraseña para autenticación

DEFINE FONT oFont NAME "Arial" SIZE 0, -16

DEFINE DIALOG oDlg FROM 0, 0 TO 455, 703 PIXEL ;
COLORS CLR_BLUE, CLR_HBROWN ;
TITLE "CDOSYS Collaboration Data Objects for Windows 2000" ;
STYLE nOR( DS_MODALFRAME, WS_POPUP, WS_CAPTION, WS_SYSMENU, WS_3DLOOK )

@ 10, 5 SAY aCtl[ 1 ] PROMPT "Servidor de Correo:" OF oDlg ;
FONT oFont UPDATE ;
COLORS CLR_BLUE, CLR_HBROWN SIZE 70, 11 PIXEL

@ 10, 80 GET aCtl[ 2 ] VAR cMailServer OF oDlg ;
FONT oFont UPDATE PICTURE "@K" ;
COLORS CLR_BLUE, CLR_WHITE SIZE 264, 11 PIXEL

@ 24, 5 SAY aCtl[ 3 ] PROMPT "Remitente:" OF oDlg ;
FONT oFont UPDATE ;
COLORS CLR_BLUE, CLR_HBROWN SIZE 70, 11 PIXEL

@ 24, 80 GET aCtl[ 4 ] VAR cFrom OF oDlg ;
FONT oFont UPDATE PICTURE "@K" ;
COLORS CLR_BLUE, CLR_WHITE SIZE 264, 11 PIXEL

@ 39, 5 SAY aCtl[ 5 ] PROMPT "Destinatario:" OF oDlg ;
FONT oFont UPDATE ;
COLORS CLR_BLUE, CLR_HBROWN SIZE 70, 11 PIXEL

@ 39, 80 GET aCtl[ 6 ] VAR cTo OF oDlg ;
FONT oFont UPDATE PICTURE "@K" ;
COLORS CLR_BLUE, CLR_WHITE SIZE 264, 11 PIXEL

@ 54, 5 SAY aCtl[ 7 ] PROMPT "Copia para:" OF oDlg ;
FONT oFont UPDATE ;
COLORS CLR_BLUE, CLR_HBROWN SIZE 70, 11 PIXEL

@ 54, 80 GET aCtl[ 8 ] VAR cBCC OF oDlg ;
FONT oFont UPDATE PICTURE "@K" ;
COLORS CLR_BLUE, CLR_WHITE SIZE 264, 11 PIXEL

@ 69, 5 SAY aCtl[ 9 ] PROMPT "Adjuntar:" OF oDlg ;
FONT oFont UPDATE ;
COLORS CLR_BLUE, CLR_HBROWN SIZE 70, 11 PIXEL

* @ 69, 80 GET aCtl[ 10 ] VAR cAttach OF oDlg PICTURE "@K" ;
* FONT oFont UPDATE Action fAddAttach( aCtl[ 10 ] ) ;
* COLORS CLR_BLUE, CLR_WHITE SIZE 264, 11 PIXEL

@ 84, 5 SAY aCtl[ 11 ] PROMPT "Asunto:" OF oDlg ;
FONT oFont UPDATE ;
COLORS CLR_BLUE, CLR_HBROWN SIZE 70, 11 PIXEL

@ 84, 80 GET aCtl[ 12 ] VAR cSubject OF oDlg ;
FONT oFont UPDATE PICTURE "@K" ;
COLORS CLR_BLUE, CLR_WHITE SIZE 264, 11 PIXEL

@ 99, 5 SAY aCtl[ 13 ] PROMPT "Autenticación: Usuario:" OF oDlg ;
FONT oFont UPDATE ;
COLORS CLR_BLUE, CLR_HBROWN SIZE 80, 11 PIXEL

@ 99, 87 GET aCtl[ 14 ] VAR cUser OF oDlg ;
FONT oFont UPDATE PICTURE "@K" ;
COLORS CLR_BLUE, CLR_WHITE SIZE 118, 11 PIXEL

@ 99,213 SAY aCtl[ 15 ] PROMPT "Contraseña:" OF oDlg ;
FONT oFont UPDATE ;
COLORS CLR_BLUE, CLR_HBROWN SIZE 44, 11 PIXEL

@ 99,259 GET aCtl[ 16 ] VAR cPass OF oDlg ;
FONT oFont UPDATE PICTURE "@K";
COLORS CLR_BLUE, CLR_WHITE SIZE 85, 11 PIXEL

@118, 6 SAY aCtl[ 17 ] PROMPT "Cuerpo del mensaje" FONT oFont UPDATE PIXEL ;
COLORS CLR_BLUE, CLR_HBROWN

@126, 10 GET aCtl[ 18 ] VAR cBody OF oDlg ;
FONT oFont MULTILINE UPDATE ;
COLORS CLR_BLUE, CLR_WHITE SIZE 330, 72 PIXEL

@208,213 BUTTON aCtl[ 19 ] PROMPT "&Enviar" OF oDlg ;
SIZE 53, 16 PIXEL ;
ACTION fSendMail( cMailServer, cFrom, cTo, cSubject, cBody, cAttach, cBCC, cUser, cPass, nPort )

@208,292 BUTTON aCtl[ 20 ] PROMPT "&Salir" OF oDlg ;
SIZE 53, 16 PIXEL ACTION oDlg:End()

ACTIVATE DIALOG oDlg CENTERED ;
VALID ( oFont:End(), .T. )

Return Nil

//---------------------------------------------------------------------------------------------//

Function fSendMail( cMailServer, cFrom, cTo, cSubject, cBody, cAttach, cBCC, cUser, cPass, nPort )

Local oCfg, oMsg, oError, ;
lAuth := ! Empty( cUser ) .and. ! Empty( cPass ), ;
nSendOpt := 2 // send using: 1 = pickup folder 2 = port 3 = remote mail server

Default nPort := 25, ;
cSubject := "", ;
cBody := ""

CursorWait()

Try
oCfg := CreateObject( "CDO.Configuration" )

With Object oCfg:Fields
:Item( cdoSMTPServer ):Value := Trim( cMailServer )
:Item( cdoSMTPServerPort ):Value := nPort
:Item( cdoSendUsing ):Value := nSendOpt

If lAuth
:Item( cdoSMTPAuthenticate ):Value := 1
:Item( cdoSendUserName ):Value := Trim( cUser )
:Item( cdoSendPassword ):Value := Trim( cPass )
:Item( cdoSMTPUseSSL ):Value := 1
EndIf

:Update()
End With


oMsg := CreateObject( "CDO.Message" )

With Object oMsg
:Configuration := oCfg
:From := Trim( cFrom )
:To := Trim( cTo )
:Subject := Trim( cSubject )
:TextBody := Trim( cBody )

If ! Empty( cAttach )
:AddAttachment := Trim( cAttach )
EndIf

If ! Empty( cBCC )
:BCC := Trim( cBCC )
EndIf

:Send()
End With

Catch oError
CursorArrow()
MsgStop( "No se pudo enviar el mensaje" + CRLF + "Error: " + cValToChar( oError:GenCode) + CRLF + ;
"SubC: " + cValToChar( oError:SubCode ) + CRLF + "OSCode: " + cValToChar( oError:OsCode ) + CRLF + ;
"SubSystem: " + cValToChar( oError:SubSystem ) + CRLF + "Mensaje: " + oError:Description )

oCfg := Nil
oMsg := Nil
Return Nil
End Try

oCfg := Nil
oMsg := Nil
SndPlaySound( GetWinDir() + "\media\Tada.wav", 0 )
CursorArrow()

Return Nil

//---------------------------------------------------------------------------------------------//

Static Function fAddAttach( oGet )

Local cFile, ;
cAttach := oGet:VarGet()

cFile := cGetFile( "*.*", "Selecciona el archivo" )

If ! Empty( cFile )
cAttach := Lower( PadR( AllTrim( cAttach ) + If( ! Empty( cAttach ), ",", "" ) + AllTrim( cFile ), 180 ) )
EndIf

oGet:cText( cAttach )

Return Nil

//---------------------------------------------------------------------------------
El include, está intacto, asi:


#ifndef _CDOSYS_CH
#define _CDOSYS_CH
#define cdoSMTPServer "http://schemas.microsoft.com/cdo/configuration/smtpserver"
#define cdoSMTPServerPort "http://schemas.microsoft.com/cdo/configuration/smtpserverport"
#define cdoSendUsing "http://schemas.microsoft.com/cdo/configuration/sendusing"
#define cdoSMTPPickupFolder "http://schemas.microsoft.com/cdo/configuration/smtpserverpickupdirectory"
#define cdoSMTPAuthenticate "http://schemas.microsoft.com/cdo/configuration/smtpauthenticate"
#define cdoSendUserName "http://schemas.microsoft.com/cdo/configuration/sendusername"
#define cdoSendPassword "http://schemas.microsoft.com/cdo/configuration/sendpassword"
#define cdoSMTPUseSSL "http://schemas.microsoft.com/cdo/configuration/smtpusessl"
#endif

//------------------------------------------------------------
He probado con www.google.com, www.yahoo.com
Utilizo FWH 7.12 y xHARBOUR build 1.1.0 intl. (simplex) (rev 6195) Borland C++ 5.51

Un saludo muy cordial.
Francisco J. Alegría P.
Chinandega, Nicaragua.

Fwxh-MySql-TMySql
User avatar
FranciscoA
 
Posts: 2158
Joined: Fri Jul 18, 2008 1:24 am
Location: Chinandega, Nicaragua, C.A.
Top

Re: enviar emails desde fwh

Postby mmercado » Wed Feb 25, 2009 4:46 am

FranciscoA wrote:He probado con http://www.google.com, http://www.yahoo.com
Hola Francisco:

Ya veo, la diferencia es que yo uso como servidor de correo el de mi proveedor de internet (smtp.prodigy.net.mx), y tú estás tratando de enviarlo a través de un servidor externo. En teoría ésto es posible, solo debemos encontrar la configuración adecuada tanto del objeto cdo message como del Firewall para permitir la conexión del servidor remoto a través del puerto 25 o de alguno otro.

Seguiré investigando, creeme que vale la pena, te informaré luego.

Un abrazo.

Manuel Mercado
manuelmercado at prodigy dot net dot mx
User avatar
mmercado
 
Posts: 782
Joined: Wed Dec 19, 2007 7:50 am
Location: Salamanca, Gto., México
Top

Re: enviar emails desde fwh

Postby Carlos Mora » Wed Feb 25, 2009 2:32 pm

Ya veo cual es el problema!

Google no usa el puerto 25 para la conexión smtp. Bájate los ejemplos de harbouradvisor, que estan hecho todos con gmail.
Yahoo solo provee smtp como servicio pago, gratis no.
Hotmail no estoy seguro porque no lo uso seguido, pero creo que tampoco te dá smtp.

¿No tienes un servidor de correos normal, el de tu proveedor de internet?

Acá un ejemplo con una cuenta de gmail, que esta creada para hacer pruebas (y poder publicar la contraseña):

Code: Select all  Expand view
// Si usas Harbour, esto hace compatible TRY CATCH
   #xcommand TRY              => BEGIN SEQUENCE WITH {|o| break(o)}
   #xcommand CATCH [<!oErr!>] => RECOVER [USING <oErr>] <-oErr->
   #xcommand FINALLY          => ALWAYS

Procedure Main()

   Local loCfg, loMsg, oError

   SetMode( 25, 80 )

   TRY
      loCfg := CREATEOBJECT( "CDO.Configuration" )
      WITH OBJECT loCfg:Fields
         :Item( "http://schemas.microsoft.com/cdo/configuration/smtpserver" ):Value := "smtp.gmail.com"
         :Item( "http://schemas.microsoft.com/cdo/configuration/smtpserverport" ):Value := 465
         :Item( "http://schemas.microsoft.com/cdo/configuration/sendusing" ):Value := 2
         :Item( "http://schemas.microsoft.com/cdo/configuration/smtpauthenticate" ):Value := .T.
         :Item( "http://schemas.microsoft.com/cdo/configuration/smtpusessl" ):Value := .T.
         :Item( "http://schemas.microsoft.com/cdo/configuration/sendusername" ):Value := "testcdo@gmail.com"
         :Item( "http://schemas.microsoft.com/cdo/configuration/sendpassword" ):Value := "prueba2345"
         :Update()
      END WITH


      loMsg := CREATEOBJECT ( "CDO.Message" )
      WITH OBJECT loMsg
         :Configuration = loCfg
         :From = "testcdo@gmail.com"
         :To = "carlosantoniomora@gmail.com"    // <-----       Coloca ac  tu direcci¢n de correo
         :Subject = "Prueba con CDO"
         :TextBody = "Este es un mensaje de prueba con CDO desde Harbour."
         :Send()
      ENDWITH

   CATCH oError
      Alert( "No se pudo enviar el mensaje" + ";"  + ;
             "Error: " + TRANSFORM(oError:GenCode, NIL) + ";" + ;
             "SubC: " + TRANSFORM(oError:SubCode, NIL) + ";" + ;
             "OSCode: " + TRANSFORM(oError:OsCode, NIL) + ";" + ;
             "SubSystem: " + TRANSFORM(oError:SubSystem, NIL) + ";" + ;
               "Mensaje: " + oError:Description )

   END

   RETURN


Este código es Harbour puro, no necesita ni siquiera FW.

Seguro que despues lo puedes adaptar.
Saludos
Carlos Mora
http://harbouradvisor.blogspot.com/
StackOverflow http://stackoverflow.com/users/549761/carlos-mora
“If you think education is expensive, try ignorance"
Carlos Mora
 
Posts: 989
Joined: Thu Nov 24, 2005 3:01 pm
Location: Madrid, España
Top

Re: enviar emails desde fwh

Postby triumvirato » Wed Feb 25, 2009 4:58 pm

Manuel,

Muchas gracias por sus aportaciones, me resultan siempre siempre muy muy interesantes, pero no soy capaz de hacerlas funcionar en Vista Home Premium.
Yo con el segundo ejemplo que publica, sigo teniendo el mismo error:

Error:1001
subc: 3
oscode: 0
subsystem: CDO.message
Mensaje: DISP_E_MEMBERNOTFOUND.

Y por otra parte, comentar que en el segundo ejemplo publicado, existe un error de sintaxis que genera un error al compilar, en el segundo END WITH, que aparece escrito todo junto y ha de ser separado.
Intentaré indagar más sobre ese error DISP_E_MEMBERNOTFOUND, que si no voy desencaminado, es que no se está creando el objeto en sí.

GRACIAS y saludos!
triumvirato
 
Posts: 199
Joined: Tue Apr 22, 2008 9:54 am
Location: Valladolid, Spain.
Top

Re: enviar emails desde fwh

Postby FranciscoA » Wed Feb 25, 2009 11:17 pm

Estimado Manuel: Tu ejemplo me funcionó perfectamente, en Gmail.com, cambiando el No. de Puerto de 25 a 465, lo cual hice basándome en el ejemplo de Carlos.

Carlos: Tu código funciona perfectamente en Gmail.com.

Gracias a ambos por sus aportes y orientaciones.
Francisco J. Alegría P.
Chinandega, Nicaragua.

Fwxh-MySql-TMySql
User avatar
FranciscoA
 
Posts: 2158
Joined: Fri Jul 18, 2008 1:24 am
Location: Chinandega, Nicaragua, C.A.
Top

Re: enviar emails desde fwh

Postby triumvirato » Thu Feb 26, 2009 7:09 am

FranciscoA wrote:Estimado Manuel: Tu ejemplo me funcionó perfectamente, en Gmail.com, cambiando el No. de Puerto de 25 a 465, lo cual hice basándome en el ejemplo de Carlos.

Carlos: Tu código funciona perfectamente en Gmail.com.

Gracias a ambos por sus aportes y orientaciones.


Francisco, te han funcionado desde Vista? podrías indicarnos el S.O.? GRACIAS

Saludos!

PD: Podría alguien enviarme el exe del segundo ejemplo de Manuel para probarlo aquí?
Last edited by triumvirato on Wed Feb 10, 2010 11:09 am, edited 1 time in total.
triumvirato
 
Posts: 199
Joined: Tue Apr 22, 2008 9:54 am
Location: Valladolid, Spain.
Top

Re: enviar emails desde fwh

Postby FranciscoA » Thu Feb 26, 2009 12:41 pm

Hola David. Unicamente lo he probado en XP. Te he enviado email utilizando el de Manuel. Te envio el ejecutable.
Saludos.
Francisco J. Alegría P.
Chinandega, Nicaragua.

Fwxh-MySql-TMySql
User avatar
FranciscoA
 
Posts: 2158
Joined: Fri Jul 18, 2008 1:24 am
Location: Chinandega, Nicaragua, C.A.
Top

Re: enviar emails desde fwh

Postby Patricio Avalos Aguirre » Thu Feb 26, 2009 12:45 pm

Hola

Al colocar correo saliente SMTP.HOTMAIL.COM envia el error, prueba cambiando el servidor de correo saliente, a mi me funciona bien con mi smtp saliente
Saludos
Patricio

__________________________________________________________________
Version: Harbour 3.2.0dev (r1307082134),Compiler: Borland C++ 5.8.2 (32-bit)
PCode version: 0.3, FWH 13.2
http://www.sialm.cl
User avatar
Patricio Avalos Aguirre
 
Posts: 1060
Joined: Fri Oct 07, 2005 1:56 pm
Location: La Serena, Chile
Top

Re: enviar emails desde fwh

Postby triumvirato » Thu Feb 26, 2009 4:36 pm

Francisco,

Muchas gracias por tu envío, funcionó correctamente, por lo que no es problema de Vista x64, sino de MI VISTA (estaba metiendo la pata en lo básico). Muchas gracias por tu ayuda y tu tiempo.

Patricio,

Correcto, el problema es del smtp, hay que configurar correctamente varios parámetros. Muchas gracias.

Saludos!!!!
triumvirato
 
Posts: 199
Joined: Tue Apr 22, 2008 9:54 am
Location: Valladolid, Spain.
Top

Re: enviar emails desde fwh

Postby MANOLO » Thu Feb 26, 2009 4:40 pm

hola patricio me puedes enviar el ejemplo

Yo no logró que funcione

Gracias
MANOLO
 
Posts: 87
Joined: Sun Oct 09, 2005 8:49 pm
Location: Spain
Top

Re: enviar emails desde fwh

Postby MANOLO » Thu Feb 26, 2009 6:59 pm

hola carlos, ya me funciona el envio de emails sin adjuntar ficheros.

tienes un ejemplo que como hacer para enviar ficheros adjuntos desde cdo.

yo lo hago así, pero no funciona:

cAttach:="f:\nuevo\factu.txt"

Code: Select all  Expand view
     loMsg := CREATEOBJECT ( "CDO.Message" )
      WITH OBJECT loMsg
         :Configuration = loCfg
         :From = "micorreo@hotmail.com"
         :To = "to@hotmail.com;to2@hotmail.com"    // <-----       Coloca ac  tu direcci¢n de correo
         :Subject = "Fichero de Salidas"
         :AddAttachment := cAttach
         :TextBody = "Adjunto le enviamos el fichero con las salidas de hoy " + dtoc(date()) + CRLF + CRLF + ;
               "Sobre Cualquier Problema debe dirigirse al dpto. de Salidas. "

         :Send()
      ENDWITH
 


Gracias
MANOLO
 
Posts: 87
Joined: Sun Oct 09, 2005 8:49 pm
Location: Spain
Top

Re: enviar emails desde fwh

Postby Patricio Avalos Aguirre » Thu Feb 26, 2009 7:02 pm

Manolo

El ejemplo es el mismo de ha colocado el maestro Manuel Mercado, solo hize copy y paste :-)

puedes hecharle un vistaso a la pagina de carlos mora ahi explica este metodo de enviar correo

http://harbouradvisor.blogspot.com/
Saludos
Patricio

__________________________________________________________________
Version: Harbour 3.2.0dev (r1307082134),Compiler: Borland C++ 5.8.2 (32-bit)
PCode version: 0.3, FWH 13.2
http://www.sialm.cl
User avatar
Patricio Avalos Aguirre
 
Posts: 1060
Joined: Fri Oct 07, 2005 1:56 pm
Location: La Serena, Chile
Top
PreviousNext
Post a reply

Return to FiveWin para Harbour/xHarbour

Who is online

Users browsing this forum: Google [Bot], nageswaragunupudi and 54 guests

Powered by phpBB © 2000, 2002, 2005, 2007 phpBB Group