Changing itemlist in a combobox

[driessen]

Hello,

I think I asked this question some years ago, but I can't it find it anymore, nore do I remember the solution that was given then.

This is my question:

In a window, I use a combobox. The list that is defined, need to be changed, depending on changing the data in the window.

How can I change a itemlist of an active combobox in my window?

Thank you very much in advance for any help.

[Marc Venken]

Changing the Array ?

http://fivetechsupport.com/forums/viewtopic.php?p=253129&sid=3f9d268fcc951d1bf053930a22ed9d1e#p253129

[cmsoft]

Driessen:
Algo asi?

Code: Select all  Expand view

#include "fivewin.ch"
function Prue_Combo()
   local oDlg, oCom1, oCom2, cVar1, cVar2
   local aList1, aList2

   aList1 := {"Opcion1","Opcion2"}

   aList2 := {"Opcion 1 - Item 1", "Opcion 1 - Item2", "Opcion 1 - Iteme3"}
   
   cVar1 := aList1[1]

   cVar2 := aList2[1]



   DEFINE DIALOG oDlg FROM 1,1 TO 300, 600 PIXEL TITLE "Combobox Relacionados"

   @ 20, 10 COMBOBOX oCom1 VAR cVar1 ITEMS aList1 SIZE 130,200 PIXEL OF oDlg ;
            ON CHANGE ( aList2:=MiFunction(oCom1),oCom2:SetItems(aList2 ), oCom2:Set(aList2[1]))

   @ 20,160 COMBOBOX oCom2 VAR cVar2 ITEMS aList2 SIZE 130,200 PIXEL OF oDlg
   
   @ 100,(300/2)-(100/2) BUTTON "Ok" SIZE 100, 20 PIXEL OF oDlg ;
            ACTION oDlg:End()

 
   ACTIVATE DIALOG oDlg CENTERED

return nil

Function MiFunction(oCom1)
local aResp
IF oCom1:nAt = 1
   aResp :=  {"Opcion 1 - Item 1", "Opcion 1 - Item 2", "Opcion 1 - Iteme 3"}
   ELSE
   aResp := {"Opcion 2 - Item 1", "Opcion 2 - Item 2", "Opcion 2 - Item 3","Opcion 2 - Item 4"}
ENDIF
Return aResp