OS Error .EXE is Not Responding

[shri_fwh]

Dear All ,

I got the below error when application was running.

Could you please guide me on this. Thanks in advance...!

Code: Select all  Expand view

Description:
  A problem caused this program to stop interacting with Windows.

Problem signature:
  Problem Event Name:   AppHangB1
  Application Name: vimfa.exe
  Application Version:  0.0.0.0
  Application Timestamp:    00000000
  Hang Signature:   521e
  Hang Type:    0
  OS Version:   6.1.7601.2.1.0.256.48
  Locale ID:    1033
  Additional Hang Signature 1:  521e9c610211bde94178e59d988aade6
  Additional Hang Signature 2:  ba33
  Additional Hang Signature 3:  ba3395d0c97c9a5a3e9ecff21551e88e
  Additional Hang Signature 4:  521e
  Additional Hang Signature 5:  521e9c610211bde94178e59d988aade6
  Additional Hang Signature 6:  ba33
  Additional Hang Signature 7:  ba3395d0c97c9a5a3e9ecff21551e88e

Read our privacy statement online:
  http://go.microsoft.com/fwlink/?linkid=104288&clcid=0x0409

If the online privacy statement is not available, please read our privacy statement offline:
  C:\Windows\system32\en-US\erofflps.txt

 

Thanks
Shridhar

[Antonio Linares]

Please check if a log file has been created in the same folder where your EXE is

[shri_fwh]

Dear Antonio ,

I do not see any log file in the .EXE folder.

Thanks
Shridhar

[Antonio Linares]

Are you able to reproduce it ?

[shri_fwh]

Dear Antonio ,

Yes I am able to reproduce it. But no any log file generated to debug the error message.


Thanks
Shridhar

[Antonio Linares]

Are you able to reproduce it on a little test that you may send me ?

[shri_fwh]

Dear Antonio ,

There are 6-7 PROCEDURE/FUNCTION levels, I need to arrange them into one file to be able to send you.


Thanks
Shridhar

[karinha]

https://support.esri.com/en/technical-article/000011555

[shri_fwh]

Dear Antonio ,

Finally ERROR has been revealed. The issue is related with Garbage Value on Multiply Topic.

Conclusion : The XBROWSE Method MakeTotals() does not work when Garbage value populated in the Data source.

Given below code is for the same, after executing the code you will see the XBROWSE grid and you need to provide the same either of the value which is already being displayed in the XBROWSE gird. As soon as you entered the same value the App.EXE goes hang.

Code: Select all  Expand view

#include "fivewin.ch"


function main
  local oDlg
  local oFont
  local nRate := 597.67
  local nQTy := 100
  local nAmt := ( nRate *  nQTy )
  local aoGET := Array(5)
  local oBrw
  local aInvData := {{ "Prd 1" , 597.67 , 100 , 0 } }



   DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
   DEFINE DIALOG oDlg SIZE 900,700 PIXEL TRUEPIXEL FONT oFont

   @ 020, 020 XBROWSE oBrw SIZE 540, 200 PIXEL OF oDlg FONT oApp:oFontGet  ;
      DATASOURCE aInvData ;
      COLUMNS 1, 2, 3, 4  ;
      HEADERS "Item ", "Rate",  "Qty.",  "Amount" ;
      PICTURES NIL,    "@Z 99,999.99", "@Z 99,999", "@Z 99,99,999.99" ;
      COLSIZES 200,    100,100, 110 ;
      CELL LINES NOBORDER FASTEDIT FOOTERS

   WITH OBJECT oBrw:aCols[ 2 ]

      :nEditType     = EDIT_GET
      :bEditValid := < | oGet |

                     oBrw:aCols[ 4 ]:Value := ( oGet:VarGet()  * oBrw:aCols[ 3 ]:Value ) // Rate * Qty
                     oBrw:MakeTotals()
                     oBrw:Refresh()

                     return .t.
                     >

   END

   WITH OBJECT oBrw:aCols[ 3 ]

      :nEditType     = EDIT_GET
      :bEditValid := < | oGet |

                     oBrw:aCols[ 4 ]:Value := ( oBrw:aCols[ 2 ]:Value  * oGet:VarGet() ) // Rate * Qty
                     oBrw:MakeTotals()
                     oBrw:Refresh()

                     return .t.
                     >

   END

   WITH OBJECT oBrw

      :CreateFromCode()
   END


//PICTURE "@Z 99,99,99,99,999.99"
   ACTIVATE DIALOG oDlg


return nil


 

[Antonio Linares]

Dear Shridhar,

Many thanks for your great feedback

We are currently checking this topic and hopefully we will publish a solution for it asap.

[shri_fwh]

Dear Antonio ,

Any news on this ?


Thanks
Shridhar

[nageswaragunupudi]

Please try this code

Code: Select all  Expand view

#include "fivewin.ch"

function Main()

  local oDlg
  local oFont
  local nRate := 597.67
  local nQTy := 100
  local nAmt := ( nRate *  nQTy )
  local aoGET := Array(5)
  local oBrw
  local aInvData := {{ "Prd 1" , 597.67 , 100 , 0 } }
  local aBlank := { Space( 5 ), 0.00, 0.00, 0.00 }

   DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
   DEFINE DIALOG oDlg SIZE 900,700 PIXEL TRUEPIXEL FONT oFont

   @ 020, 020 XBROWSE oBrw SIZE 540, 200 PIXEL OF oDlg FONT oFont  ;
      DATASOURCE aInvData ;
      COLUMNS 1, 2, 3, 4  ;
      HEADERS "Item ", "Rate",  "Qty.",  "Amount" ;
      PICTURES NIL,    "@Z 99,999.99", "@Z 99,999", "@Z 99,99,999.99" ;
      COLSIZES 200,    100,100, 110 ;
      CELL LINES NOBORDER FASTEDIT FOOTERS

   WITH OBJECT oBrw:aCols[ 1 ]
      :nEditType     = EDIT_GET
   END

   WITH OBJECT oBrw:aCols[ 2 ]
      :bEditWhen     = { || !Empty( oBrw:aRow[ 1 ] ) }
      :nEditType     = EDIT_GET
   END

   WITH OBJECT oBrw:aCols[ 3 ]
      :bEditWhen     = { || !Empty( oBrw:aRow[ 1 ] ) }
      :nEditType     = EDIT_GET
      :nFooterType   = AGGR_SUM
   END

   WITH OBJECT oBrw:aCols[ 4 ]
      :bEditValue    = { || oBrw:aRow[ 4 ] := oBrw:aRow[ 2 ] * oBrw:aRow[ 3 ] }
      :nFooterType   = AGGR_SUM
   END

   WITH OBJECT oBrw
      :bClrStd    := { || { CLR_BLACK, If( Empty( oBrw:aRow[ 1 ] ), CLR_YELLOW, CLR_WHITE ) } }

      :bPastEof   := <||
         if !Empty( oBrw:aRow[ 1 ] )
            AAdd( oBrw:aArrayData, AClone( aBlank ) )
            oBrw:GoDown()
         endif
         return nil
         >

      :bChange    := <||
         if oBrw:nArrayAt < Len( oBrw:aArrayData )
            if Empty( ATail( oBrw:aArrayData )[ 1 ] )
               ASize( oBrw:aArrayData, oBrw:nLen - 1 )
               oBrw:Refresh()
            endif
         endif
         return nil
         >

      :MakeTotals()
      :CreateFromCode()
   END

   ACTIVATE DIALOG oDlg CENTERED

return nil
 

[shri_fwh]

Dear Sir ,

Many Thanks for this XBROWSE code pattern, I am rewriting my existing code with this pattern.


Thanks
Shridhar