To Nages Insert images on xbrowse

[Silvio.Falconi]

Dear Nages, remeber this topic?
http://forums.fivetechsupport.com/viewtopic.php?f=3&t=35687&p=212509#p212509

I wish create a Xbrowse as this


Each row ( one record) must have ;

First Last
phone 444 44 444 4444 phone2 77 777 77777
Address xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
city xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
Note aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa


with small images on each record /field as you see on picture

Ho I can make it ?

[cnavarro]

Something like that?

[nanoespinoza]

Dear Cristobal

Very nice and interesting, could you give an example of how it does it?

Cheers

[cnavarro]

Dear Fernando
Define your columns normaly, add image for each column

Code: Select all  Expand view

      WITH OBJECT :aCols[ 1 ]
         :bStrImage     := { || "D:\Fwh\FwhTeam\bitmaps\16x16\notes16.bmp" }
         :oDataFont     := oBold
         :nDataStrAlign := AL_CENTER + AL_VCENTER
         :nDataBmpAlign := AL_LEFT
         //:aImgRect      := { 4, 4, 32, 32 }
      END

 

And then, define your SetColsAsRows

[fraxzi]

Mr. Navarro,

How to add the 'AGE' along side with the 'NAME?

[nanoespinoza]

Perfect, thanks

Dear Fernando
Define your columns normaly, add image for each column

Code: Select all  Expand view

      WITH OBJECT :aCols[ 1 ]
         :bStrImage     := { || "D:\Fwh\FwhTeam\bitmaps\16x16\notes16.bmp" }
         :oDataFont     := oBold
         :nDataStrAlign := AL_CENTER + AL_VCENTER
         :nDataBmpAlign := AL_LEFT
         //:aImgRect      := { 4, 4, 32, 32 }
      END

 

And then, define your SetColsAsRows

[cnavarro]

Mr. Navarro,

How to add the 'AGE' along side with the 'NAME?

Age is other column

With new syntax

Code: Select all  Expand view

   @ 0, 0 XBROWSE oBrw OF oWnd ;
      DATASOURCE "Cust" ;
      COLUMNS "TRIM(FIRST)+', '+TRIM(LAST) AS FullName PICTURE @! WIDTH 350 SORT FIRST", ;
      "'Street: ' + TRIM(STREET) AS Street WIDTH 350", ;
      "'City: ' + TRIM(CITY) AS Address WIDTH 350 SORT CITY", ;
      "'Age: ' + StrZero( AGE, 2 ) WIDTH 200" ;
      CELL LINES NOBORDER PIXEL AUTOSORT

   WITH OBJECT oBrw
      :lHeader          := .F.
      :lRecordSelector  := .F.
      :lHScroll         := .F.

       // Important for not separate NAME with AGE
      :nColDividerStyle := LINESTYLE_NOLINES

      :nRowDividerStyle := LINESTYLE_DARKGRAY //LIGHTGRAY //
      :nRowHeight       := 72

.../...
    END
   // Column AGE is not included
   :aCols[ 1 ]:SetColsAsRows( { 1, 2, 3 } )

 

[Silvio.Falconi]

Navarro,
I try it but make me error



I have the browse at left and the fields at right on a dialog

I use my archive and not run also bchange
I sent you mt small test

[cnavarro]

You need last version of Fw for new syntax definition of columns in xbrowse
I have answered your mail

[Silvio.Falconi]

I try this :

Code: Select all  Expand view

@ 30,0 XBROWSE oBrowse OF oDlg DATASOURCE "CL" ;
          COLUMNS "CLNombre","CLDirecc","CLlocali","CLCap","CLProv","CLTELEFONO","CLMOVIL" ;
          HEADERS "Ragione Sociale", "Indirizzo", nil, nil, "Dettagli" ;
          CELL LINES NOBORDER


        WITH OBJECT oBrowse
         WITH OBJECT :aCols[ 1 ]
         :bStrImage     := { || "phone.bmp" }
        * :oDataFont     := oBold
         :nDataStrAlign := AL_CENTER + AL_VCENTER
         :nDataBmpAlign := AL_LEFT
         //:aImgRect      := { 4, 4, 32, 32 }
      END

       *  WITH OBJECT oBrw
          :aCols[ 1 ]:SetColsAsRows( 1,6,2,3 )
          :aCols[ 2 ]:SetColsAsRows( 2, 3, 4 )
          :aCols[ 5 ]:SetColsAsRows( 5, 6, 7 )
          //
      :lHeader          := .F.
      :lRecordSelector  := .F.
      :lHScroll         := .F.

       // Important for not separate NAME with AGE
      :nColDividerStyle := LINESTYLE_NOLINES

      :nRowDividerStyle := LINESTYLE_DARKGRAY //LIGHTGRAY //
      :nRowHeight       := 72
          :CreateFromCode()
       END


 

the result is





But I wish this


any solution ?

[Silvio.Falconi]

Now I found another sample of Nages Compatible with my release of fivewin.

the source test

Code: Select all  Expand view

#include "fivewin.ch"

function colsasrows2()

   local oWnd, oBrw, oFont, aCols
   local nLine    := 0

   USE CUSTOMER ALIAS CUST

 //  xbrowse()

   DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
   DEFINE WINDOW oWnd
   oWnd:SetFont( oFont )

   aCols := { ;
      { { || If( nLine == 0, STR(CUST->ID,4), "" ) }, "ID" }, ;
      { { || If( nLine == 0, CUST->FIRST+" "+CUST->LAST, If( nLine == 1,  CUST->ZIP, CUST->ZIP ) ) }, "CustName" }, ;
      { { || If( nLine == 0, CUST->STREET, If( nLine == 1, CUST->CITY, CUST->ZIP ) ) }, "Address" }, ;
      { { || If( nLine == 0, DTOC(CUST->HIREDATE), If( nLine == 1, Str( CUST->AGE, 2 ), TRANSFORM( CUST->SALARY,"9,999,999.99") ) ) }, "Details" } }



   @ 0,0 XBROWSE oBrw OF oWnd DATASOURCE "CUST" ;
      COLUMNS aCols ;
      CELL LINES NOBORDER

   // Navigation blocks
   oBrw:bGoTop    := { || nLine := 0, ( oBrw:cAlias )->( DBGOTOP()    ) }
   oBrw:bGoBottom := { || nLine := 2, ( oBrw:cAlias )->( DBGOBOTTOM() ) }
   oBrw:bKeyCount := { || ( oBrw:cAlias )->( OrdKeyCount() ) * 3 }
   oBrw:bKeyNo    := { || ( ( oBrw:cAlias )->( OrdKeyNo() - 1 ) * 3 ) + 1 + nLine  }
   oBrw:bSkip     := { |nSkip| ( oBrw:cAlias )->( MySkipper( nSkip, @nLine ) ) }
   oBrw:bKeyNo := { |n| If( n != nil, ( n--, ( oBrw:cAlias )->( OrdKeyGoTo( Int( n / 3 ) + 1 ) ), nLine := n % 3 ), nil ), ;
                        ( ( oBrw:cAlias )->( OrdKeyNo() - 1 ) * 3 ) + 1 + nLine }
   oBrw:bBookMark := { |n| If( n != nil, ( n--, ( oBrw:cAlias )->( DbGoTo( Int( n / 3 ) + 1 ) ), nLine := n % 3 ), nil ), ;
                        ( ( oBrw:cAlias )->( RecNo() - 1 ) * 3 ) + 1 + nLine }


   WITH OBJECT oBrw
      :aCols[ 1 ]:nDataStrAlign := AL_RIGHT


      :aCols[ 2 ]:bLeftText   := { || If( nLine == 0, "", If( nLine == 1, "Phone1", "Phone2:" ) ) }
      :aCols[ 2 ]:bStrImage     :=  { || If( nLine == 0, "", If( nLine == 1, "phone.bmp", "phone2.bmp" ) ) }
      :aCols[ 2 ]:nDataBmpAlign := AL_RIGHT

      :aCols[ 3 ]:bStrImage     :=  { || If( nLine == 0, "address.bmp", If( nLine == 1, "city.bmp", "note.bmp" ) ) }
      :aCols[ 3 ]:nDataBmpAlign := AL_RIGHT
      :aCols[ 3 ]:nWidth      := 340
      :aCols[ 3 ]:bLeftText   := { || If( nLine == 0, "Address:", If( nLine == 1, "City:", "Cap:" ) ) }

      :aCols[ 4 ]:nWidth      := 140
      :aCols[ 4 ]:nDataStrAlign := AL_RIGHT
      :aCols[ 4 ]:bLeftText   := { || If( nLine == 0, "Date:", If( nLine == 1, "Age:", "Sal:" ) ) }



      :bClrStd    := { || { CLR_BLACK, If( nLine == 0, CLR_HGRAY, CLR_WHITE ) } }
      //
      :CreateFromCode()
   END
   oWnd:oClient   := oBrw

   ACTIVATE WINDOW oWnd CENTERED
   RELEASE FONT oFont

return nil

static function MySkipper( nSkip, nLine )

   local nSkipped := 0

   DEFAULT nSkip := 1

   if nSkip == 0
      return 0
   endif
   if nSkip > 0
      do while nSkipped < nSkip
         if nLine < 2
            nLine++
            nSkipped++
         else
            DBSKIP( 1 )
            if Eof()
               DBGOBOTTOM()
               EXIT
            endif
            nLine := 0
            nSkipped++
         endif
      enddo
   else
      do while nSkipped > nSkip
         if nLine > 0
            nLine--
            nSkipped--
         else
            DBSKIP( -1 )
            if BOF()
               EXIT
            endif
            nLine    := 2
            nSkipped--
         endif
      enddo
   endif

return nSkipped
 

this is the result :



Questions
1 . Can I set the font of each bLefttext ?
2. Can I move the images on Left before of bLefttext ?
3. When I select a record can have one record as one Row ? ( with a box arround)

thanks

[Silvio.Falconi]

This is the last my release



I can Add, edit and delete record, also scroll ( prev/next) record.


I wish to have on xbrowse the record with two columns and 5 lines on white backgroung and a line box to determine a record
as this picture




How I can make it