circolar grapphics

[Silvio.Falconi]

One customer ask me if I can insert on a Services 's Report ( Fattura) a circolar graph statistic

as this



is there someone can help me to modify the tgraph class to understand how make it ?

[nageswaragunupudi]

Code: Select all  Expand view

#include "fivewin.ch"

function Main()

   local oWnd, aChart   := {}
   local aVal    := { 2500, 500, 1250, 200, 860 }
   local aClr    := { CLR_GREEN, CLR_HRED, CLR_HBLUE, CLR_YELLOW, CLR_MAGENTA }

   aChart   := MakeDnChart( aVal, aClr )

   DEFINE WINDOW oWnd TITLE "FWH : DRAW SHAPES"
   oWnd:nWidth    := 800
   oWnd:nHeight   := 800
   ACTIVATE WINDOW oWnd CENTERED ;
       ON PAINT oWnd:DrawShapes( aChart, { 100, 100, 500, 500 } )

return nil

function MakeDnChart( aVal, aClr )

   local aChart   := {}
   local aSweep   := {}
   local nTotal   := 0
   local n, nAngle   := -90

   AEval( aVal, { |n| nTotal += n } )
   AEval( aVal, { |n| AAdd( aSweep, n / nTotal * 360 ) } )

   for n := 1 to Len( aVal )
      AAdd( aChart, { "PIE", aClr[ n ], 0, 1024, 1024, 0, 0, 1023, 1023, nAngle, aSweep[ n ] } )
      nAngle   += aSweep[ n ]
   next

   nAngle   := -90
   for n := 1 to Len( aVal )
      AAdd( aChart, { "PIE", CLR_WHITE, 4, 1024, 1024, 0, 0, 1023-4, 1023-4, nAngle, aSweep[ n ] } )
      nAngle   += aSweep[ n ]
   next

   AAdd( aChart, { "ELLIPSE", CLR_WHITE, 0, 1024, 1024, 255, 255, 1023 - 255, 1023 - 255 } )

return aChart
 

[Silvio.Falconi]

Wonderful great Maestro

Is there on my fwh last release ?
it run also on Tprinter class I must draw it on an Invoice (Factura)

[Enrico Maria Giordano]

Code: Select all  Expand view

AAdd( aChart, { "ELLIPSE", CLR_WHITE, 0, 1024, 1024, 255, 255, 1023 - 255, 1023 - 255 } )

Great idea!

EMG

[nageswaragunupudi]

Is there on my fwh last release ?

Avaliable from FWH 15.12 onwards.

Code: Select all  Expand view

function PrintChart( aChart )

   local oPrn
   local hBmp

   PRINT oPrn PREVIEW
   PAGE
      hBmp   :=  FW_CreateBitmap( { 4096, 4096, aChart } )
      @ 1, 1 PRINT TO oPrn IMAGE hBmp SIZE 2, 2 INCHES
      DeleteObject( hBmp )
   ENDPAGE
   ENDPRINT

return nil
 

[Silvio.Falconi]

THANKS RAO!!

[Silvio.Falconi]

Mister Rao,


I wish insert values sample " 20%" on each section on circle

and I wish write also on the center of each circle

How I can make it ?

thanks

[Silvio.Falconi]

For the text on the center I resolved !!

[nageswaragunupudi]

Sorry, I can not help with writing text on each individual pie.

[nageswaragunupudi]

Another sample showing Doughnut Charts with multiple series.

Code: Select all  Expand view

#include "fivewin.ch"

function Main()

   local oWnd, aChart   := {}
   local aVal    := {   { 2500, 500, 1250, 200, 860 }, ;
                        { 1800, 750, 1500, 300, 400 }  }

   local aClr    := { CLR_GREEN, CLR_HRED, CLR_HBLUE, CLR_YELLOW, CLR_MAGENTA }

   aChart   := MakeDnChart( aVal, aClr )

   DEFINE WINDOW oWnd TITLE "DOUGHTNUT CHART"

   @ 10,10 BUTTON "PRINT" SIZE 100,30 PIXEL OF oWnd ACTION PrintChart( aChart )

   oWnd:nWidth    := 800
   oWnd:nHeight   := 800
   ACTIVATE WINDOW oWnd CENTERED ;
       ON PAINT oWnd:DrawShapes( aChart, { 100, 100, 500, 500 } )

return nil

function MakeDnChart( aVals, aClr )

   local aVal, nSeries, nHt, aRect
   local aChart   := {}
   local aSweep   := {}
   local nTotal   := 0
   local n, nAngle

   nSeries  := Len( aVals )
   nHt      := Int( 512 / ( nSeries + 1 ))
   aRect    := { 0, 0, 1024, 1024 }

   for each aVal in aVals

      nTotal      := 0
      aSweep      := {}

      AEval( aVal, { |n| nTotal += n } )
      AEval( aVal, { |n| AAdd( aSweep, n / nTotal * 360 ) } )

      nAngle   := -90
      for n := 1 to Len( aVal )
         AAdd( aChart, { "PIE", aClr[ n ], 0, 1024, 1024, aRect[ 1 ], aRect[ 2 ], aRect[ 3 ], aRect[ 4 ], nAngle, aSweep[ n ] } )
         nAngle   += aSweep[ n ]
      next

      nAngle   := -90
      for n := 1 to Len( aVal )
         AAdd( aChart, { "PIE", CLR_WHITE, 4, 1024, 1024, aRect[ 1 ] + 2, aRect[ 2 ] + 2, aRect[ 3 ] - 2, aRect[ 4 ] - 2, nAngle, aSweep[ n ] } )
         nAngle   += aSweep[ n ]
      next

      aRect[ 1 ]     += nHt
      aRect[ 2 ]     += nHt
      aRect[ 3 ]     -= nHt
      aRect[ 4 ]     -= nHt

   next

   AAdd( aChart, { "ELLIPSE", CLR_WHITE, 0, 1024, 1024, aRect[ 1 ], aRect[ 2 ], aRect[ 3 ], aRect[ 4 ] } )

return aChart


function PrintChart( aChart )

   local oPrn
   local hBmp

   PRINT oPrn PREVIEW
   PAGE
      hBmp   :=  FW_CreateBitmap( { 4096, 4096, aChart } )
      @ 1, 1 PRINT TO oPrn IMAGE hBmp SIZE 2, 2 INCHES
      DeleteObject( hBmp )
   ENDPAGE
   ENDPRINT

return nil
 

4

[Silvio.Falconi]

RAO ...Nice it!!
Is possible insert the values of each section and show the leggend as this ?





I explain I have an archive where I calc the movements for each month from Jan to Dec .. I can send it
I wish insert on each part the name of th emonth and the value / %

[Silvio.Falconi]

Dear Nages,
a Question
If you make multiple series as you made

local aVal := { { 2500, 500, 1250, 200, 860 }, ; first serie
{ 1800, 750, 1500, 300, 400 } } second serie


you must the possibility to set also two different colors for each serie

for a sample :

I have a Family Budget application and I set for each category of entries and exits a different color

How I can modify it to have multiple colors series ?

[Silvio.Falconi]

why not modify directly tgraph class ???