:procLine - equivalente

[karinha]

Con xHarbour, funciona. Con HARBOUR NO funcona. ???

Code: Select all  Expand view

#include "FiveWin.ch"
#include "error.ch"

FUNCTION Main()

   local oError, x, nTotal, nLoc

  TRY

    nLoc := "error" / 2  // linea 10

  CATCH oError  

   msgInfo( oError:gencode )

   msgInfo( oError:SubSystem )

   msgInfo( oError:SubCode )

   msgInfo( oError:Operation )

   msgInfo( oError:Description )

   msgInfo( valToPrg( oError:Args ) )

   // Asi, con xHarbour funciona. Con Harbour NO funciona. ????
   MsgInfo( cValToChar( oError:procLine() ),, "Linea del Error: 10" )

  END

RETURN NIL

// Fin
 


Saludos.

[hmpaquito]

¿ Ha incluido vd. xHb.Lib ?

[karinha]

Code: Select all  Expand view

// Testing Harbour ProcName() and ProcLine() -> Procname.prg de Harbour

#include "FiveWin.ch"

PROCEDURE Main()

   Two()

RETURN

FUNCTION Two()

   Three()

RETURN NIL

FUNCTION Three()

   Four()

RETURN NIL

FUNCTION Four()

   Five()

RETURN NIL

FUNCTION Five()

   LOCAL n := 0

   WHILE ! Empty( ProcName( n ) )
      ?? "Called from: ", ProcName( n ), ProcLine( n++ ), hb_eol()
   ENDDO

RETURN NIL

// fin
 



[karinha]

¿ Ha incluido vd. xHb.Lib ?

Code: Select all  Expand view

echo %hdirl%\xhb.lib + >> b32.bc
 

Saludos.

[karinha]

Resuelto con BEGIN... SEQUENCE... END.

Que compilador(Harbour) complicado! xHarbour es bien mas facil.

Code: Select all  Expand view

// testing procline() con Harbour. Me gusta xHarbour. jejejejejeje.

#include "FiveWin.ch"

MEMVAR A, B

PROCEDURE Main()

   LOCAL oError

   BEGIN SEQUENCE WITH {| oError | oError:Cargo := { ProcName( 1 ),   ;
                                                     ProcLine( 1 ) }, ;
                                                     Break( oError ) }

      A=B  // linea del error: 15

   RECOVER USING oError

      ? oError:Cargo[1] //Procname
      ? oError:Cargo[2] //Procline -> Retorna Correcto con BEGIN...

   END

RETURN
 



[Antonio Linares]

muy bien

La librería hbcplr.lib de Harbour es, en mi opinión, lo que le da la superioridad a Harbour sobre xHarbour,
aunque en algunos casos, como este, efectivamente xHarbour sea más fácil.

Esta librería contiene todo el compilador y el preprocesador, lo que permite compilar y ejecutar código
desde el propio EXE y esto es la clave para construir un ERP.

[MarioG]

Karinha, Antonio
Muchas gracias por colocar o tempo na pesquisa
muchas gracias por poner tiempo en la investigación

Tendré que usar BEGIN... SEQUENCE... END

[karinha]

Gracias Master, no tengo ningún conocimiento sobre hbcplr.lib pués no uso Harbour aún. Podrias hablar más sobre la misma?

Y en españa, que significa ERP?

Gracias, saludos.

[xmanuel]

Mira aquí karinha https://es.wikipedia.org/wiki/Sistema_de_planificaci%C3%B3n_de_recursos_empresariales

Por cierto, Harbour está mucho mejor construido en todos los aspectos que xHarbour, no te quepa ni la menor duda.
Te lo digo yo que he estado trasteando por las tripas de los dos.
Además parece que xHarbour está un poquito dejado de la mano...

[karinha]

Mira aquí karinha https://es.wikipedia.org/wiki/Sistema_de_planificaci%C3%B3n_de_recursos_empresariales

Por cierto, Harbour está mucho mejor construido en todos los aspectos que xHarbour, no te quepa ni la menor duda.
Te lo digo yo que he estado trasteando por las tripas de los dos.
Además parece que xHarbour está un poquito dejado de la mano...

Gracias estimado xManuel. Saludos.