ADS connection string from remote server

[MGA]

some sample connection advantage database server connection string from remote server?

thanks

[carlos vargas]

recordar abrir el puerto indicado, y si es por por conexion wan hacer el redireccionamiento en el router.

aca COMPRESSION=Internet solo cuando la conexion en por WAN, tanto LAN como LOCAL no aplica.
ads.ini

[SETTINGS]
RETRY_ADS_CONNECTS=1
MAX_TIMEOUTS=40
COMPRESSION=Internet
USE_TCP_IP=1

aca yo cambiaba el Tipo a 1,2,3 segun como queria la conexion, si por WAN, LAN, LOCAL
aca \\SRV-DCFS-01 es el nombre del servidor.
aca \\EMPRESA.ZAPTO.ORG es un dominio dinamico que tenia con NO-IP
aca :6263 es el puerto que usa ADS.

empresa.ini

[DATOS]
Tipo=1
Conexion1=.\DATOS\DBEMPRESA.ADD
Conexion2=\\SRV-DCFS-01:6262\DATOSEMPRESA\DBEMPRESA.ADD
Conexion3=\\EMPRESA.ZAPTO.ORG:6263\DATOSEMPRESA\DBEMPRESA.ADD

conectar.prg

Code: Select all  Expand view

#include "credicom.ch"

STATIC nServer

/*-------------------------------------------------------------------------------------------------*/

FUNCTION Conectar()
   LOCAL lConectado  := FALSE
   LOCAL hArchivoIni := NIL
   LOCAL cError      := ""
   LOCAL cServidor   := ""
   LOCAL nServidor   := 0
   LOCAL bConectar   := {|| lConectado := AdsConnect60( cServidor, nServidor, "EmpresaUser", "EmpresaPassword@", NIL , @hConexion ) }
   LOCAL bAbrir      := {|| lConectado := Conectar_AbrirTablas() }

   hArchivoIni := HB_ReadIni( Lower( ".\EMPRESA.INI" ) )

   IF HB_IsNil( hArchivoIni )
      MsgStop( "No se pudo leer el archivo de configuración EMPRESA.INI, contacte al desarrollador del programa." )
      RETURN lConectado
   ELSE
      TRY
         nConexion := Val( hArchivoIni[ "DATOS", "Tipo" ] )
      CATCH
         nConexion := 0
      END
      DO CASE
      CASE nConexion==1
         nServidor := ADS_LOCAL_SERVER
         cServidor := hArchivoIni[ "DATOS", "Conexion1" ]
      CASE nConexion==2
         nServidor := ADS_REMOTE_SERVER
         cServidor := hArchivoIni[ "DATOS", "Conexion2" ]
      CASE nConexion==3
         nServidor := ADS_AIS_SERVER
         cServidor := hArchivoIni[ "DATOS", "Conexion3" ]
      OTHERWISE
         MsgStop( "El archivo de conexión esta corrupto, contacte al desarrollador del programa." )
         RETURN lConectado
      ENDCASE
   ENDIF

   IF !Empty( cServidor )
      MsgRun( "Conectando con el servidor de datos, espere un momento.", "EMPRESA", bConectar )
      IF !lConectado
         AdsGetLastError( @cError )
         MsgStop( "No se ha podido realizar la conexión al servidor de datos: " + FINL + cError + FINL + cServidor )
      ELSE
         oSesion:cPC_Servidor := RTrim( cServidor )
         MsgRun( "Abriendo tablas de datos, espere un momento", "EMPRESA", bAbrir )
      ENDIF
   ELSE
      MsgStop( "El archivo de conexión esta corrupto, contacte al desarrollador del programa." )
   ENDIF

RETURN lConectado
 

Code: Select all  Expand view

/*-------------------------------------------------------------------------------------------------*/

FUNCTION Conectar_AbrirTablas()
   LOCAL lTablasAbiertas := TRUE
   LOCAL oError

   TRY
      Conectar_AbrirTabla( "CONTROL",          "CTRL" )
      ...
      Conectar_AbrirTabla( "EMPLEADOS",       "CEMP" )
      ...
      DBSelectArea( 0 )

   CATCH oError
      lTablasAbiertas := FALSE
      ShowError( oError )
   END

RETURN lTablasAbiertas

/*-------------------------------------------------------------------------------------------------*/

PROCEDURE Conectar_AbrirTabla( cTabla, cAlias )

   USE ( cTabla ) NEW ALIAS ( cAlias ) SHARED

   IF nServer == ADS_AIS_SERVER
      AdsCacheRecords( 100 )
      SysRefresh()
      CursorWait()
   ENDIF

RETURN
 

[MGA]

Carlos,

Obrigado por responder.

Meu amigo, eu gostaria de usar o ADS como MYSQL, cliente/server em uma REDE LOCAL em precisar mapear.

Para conectar o cliente no servidor, eu não entendi como informar:

EX - MYSQL:
IP:
PORTA:
SERVER:
user:
PASS: