No me funciona la clausula password en un get desde código

[fespinoza]

Lo que he hecho es coger la función MsgGet nativa de FiveWin xHarbour 907 y modificarla para que cuando mi variable lOculto sea .T. el get se muestre como un password, pero llevo intentando de todo y buscando todo tipo de información y no consigo que funcione, nunca me aparecen los círculos negros

Code: Select all  Expand view  RUN

FUNCTION MsgGet( cTitle, cText, uVar, cBmpFile, cResName, lOculto)
LOCAL oDlg, oGet, oBmp, uTemp:=uVar, lOk:=.F., oFnt
DEFAULT cTitle:="", cText:="", lOculto:=.F.
DEFINE FONT oFnt NAME "Tahoma" SIZE 0,-12
DEFINE DIALOG oDlg FROM 10, 20 TO 18, 59.5 TITLE cTitle FONT oFnt
    IF ! Empty( cBmpFile ) .OR. ! Empty( cResName )
        IF ! Empty( cBmpFile )
            @ 1, 1 BITMAP oBmp FILENAME cBmpFile SIZE 20, 20 NO BORDER OF oDlg ADJUST TRANSPARENT
        ENDIF
        IF ! Empty( cResName )
            @ 1, 1 BITMAP oBmp RESOURCE cResName SIZE 20, 20 NO BORDER OF oDlg ADJUST TRANSPARENT
        ENDIF
        @ 0.5, 6 SAY cText OF oDlg SIZE 250, 10
        @ 1.6, 4 GET oGet VAR uTemp SIZE 80, 12 OF oDlg RIGHT PICTURE "99999999" PASSWORD
    ELSE
        @ 0.5, 3.3 SAY cText OF oDlg SIZE 250, 10
        @ 1.6, 2.3 GET oGet VAR uTemp SIZE 80, 12 OF oDlg RIGHT PICTURE "99999999" PASSWORD
    ENDIF
        IF( lOculto, oGet:lPassword:=.T., oGet:lPassword:=.F.)
        oGet:cTooltip:={ "Medite antes de ingresar cualquier valor","SicefWin "+cVersSW,1,CLR_WHITE,CLR_GREEN }
    @ 2.25, 7.5 - If( oBmp==nil, 4, 2 ) BUTTON "&Aceptar"  OF oDlg SIZE 35, 12 ACTION ( oDlg:End(), lOk:=.T. ) DEFAULT
    @ 2.25, 16.5 - If( oBmp==nil, 4, 2 ) BUTTON "&Cancelar" OF oDlg SIZE 35, 12 ACTION ( oDlg:End(), lOk:=.F. )
    oDlg:lHelpIcon:= .F.
ACTIVATE DIALOG oDlg CENTERED ON INIT oDlg:SetIcon(oApp:cIcono)
If lOk
    uVar:=uTemp
Endif
oFnt:End()
Return lOk
 

Dejo el ejemplo para ver si alguien me puede dar una mano, a ver que hago mal.

Saludos

Fernando Espinoza

[Willi Quintana]

Hola, prueba asi:
IF( lOculto, oGet:lPassword:=.T., oGet:lPassword:=.F., oGet:Refresh()

Salu2)

[Willi Quintana]

Hola, prueba asi:
IF( lOculto, oGet:lPassword:=.T., oGet:lPassword:=.F.)
oGet:Refresh()

Salu2)

[fespinoza]

Willy

Gracias por la respuesta, pero no me funciona, sigue igual.

Saludos

[Antonio Linares]

Fernando,

Prueba a quitar la claúsula RIGHT. Aqui funciona bien asi:

Code: Select all  Expand view  RUN

#include "FiveWin.ch"

//----------------------------------------------------------------------------//

function MsgGet( cTitle, cText, uVar, cBmpFile, cResName, lPassword )

   local oDlg, oBmp
   local uTemp := uVar
   local lOk   := .f.

   DEFAULT cText := "", lPassword := .F.

   DEFINE DIALOG oDlg FROM 10, 20 TO 18, 59.5 TITLE cTitle

   if ! Empty( cBmpFile ) .or. ! Empty( cResName )
      if ! Empty( cBmpFile )
         @ 1, 1 BITMAP oBmp FILENAME cBmpFile SIZE 20, 20 NO BORDER OF oDlg
      endif

      if ! Empty( cResName )
         @ 1, 1 BITMAP oBmp RESOURCE cResName SIZE 20, 20 NO BORDER OF oDlg
      endif

      @ 0.5, 6 SAY cText OF oDlg SIZE 250, 10
     
      if ! lPassword
         @ 1.6, 4 GET uTemp SIZE 120, 12 OF oDlg
      else  
         @ 1.6, 4 GET uTemp SIZE 120, 12 OF oDlg PASSWORD
      endif
   else  
      @ 0.5, 3.3 SAY cText OF oDlg SIZE 250, 10
      if ! lPassword
         @ 1.6, 2.3 GET uTemp SIZE 120, 12 OF oDlg
      else
         @ 1.6, 2.3 GET uTemp SIZE 120, 12 OF oDlg PASSWORD
      endif
   endif  

   @ 2.25, 7.5 - If( oBmp == nil, 2, 0 ) BUTTON "&Ok"  OF oDlg SIZE 35, 12 ;
      ACTION ( oDlg:End(), lOk := .t. ) DEFAULT

   @ 2.25, 16.5 - If( oBmp == nil, 2, 0 ) BUTTON "&Cancel" OF oDlg SIZE 35, 12 ;
      ACTION ( oDlg:End(), lOk := .f. )

   ACTIVATE DIALOG oDlg CENTERED

   if lOk
      uVar := uTemp
   endif

return lOk

//----------------------------------------------------------------------------//

[fespinoza]

Antonio

He probado el ejemplo suyo, pero tengo el mismo resultado, cuando lPassword es .t. o .f. no se muestra el get como un password, sino que muestra los números que se digita.

Saludos

Fernando Espinoza

[Daniel Garcia-Gil]

Fernando

Verifica que no estes pasando digitos en la variable uVar, no son aceptados, intenta pasar un string...

Code: Select all  Expand view  RUN

MsgGet( "titulo prueba", "texto", "         ", NIL, NIL, .T. )

usa el codigo qu ete recomienda Antonio sino siempre estara activo el estilo PASSWORD

[fespinoza]

Ese es el problema, porque lo uso para pasar un valor numérico, voy a ver como lo corrijo.

Gracias

Fernando Espinoza