FiveTech Software tech support forums

by **Ruben Fernandez** » Fri Nov 05, 2010 5:28 pm

Nuevo:
La linea de comandos es

ShellExecute( 0, "open", "C:\Zonainmo\emailer.exe",envio2,,, )
Donde envio2 es
envio2:=" /server:"+CorreoServidor +" /to:"+aquien+ " /subject:"+ CorreoSujeto+ " /from:"+ CorreoDir+ " /file:"+cFile+ " /username:"+CorreoUsuario+ " /password:"+CorreoPassword+ " >null"

Estimados: Necesito enviar correo por linea de comandos.
Baje Emailer y desde linea de comandos funciona muy bien, ( desde el viejo DOS, cmd nuevo), lo que no logro es hacerdo desde un programa de FWH
(Ya probe con cdosys y no me funciona)

Estas son algunas de las opciones del programa Emailer, pero no logro crear
una cadena de caracteres que lo haga funcionar desde un programa FWH. Si alguien se da idea se lo agradezco.

Muchas gracias.

EMAILER [command line options]
/server:<server>
/to:<to addresses>
/from:<from address>
[/cc:<CC addresses>]
[/bcc:<BCC addresses>]
[/subject:<subject text>]
[/body:<body text> | /file:<body text file>]
[/priority:<High|Normal|Low>]
[/port:<smtp port>]
[/domain:<domain name>]
[/username:<server username>]
[/password:<server password>]
[/attachment:<file1;file2;file3>]
[/html | /plaintext (default)]
[/ssl]
[/deliveryreport]
[/confirm (Confirm arguments before sending)]

Saludos
Ruben Fernandez

by **jll-fwh** » Sat Nov 06, 2010 2:23 am

Hola Ruben:

CDOSYS funciona perfectamente, yo lo tengo implementado y funciona OK. ( solo tienes que crearte una cuenta de gmail para poder usar el SMTP de google, lo demas es simple ). Si quieres te puedo mandar el .PRG, Si te interesa hazmelo saber.

Para en envio en Background tambien tienes la opcion de BLAT, que se usaba para CGI en FWH para en envio de correos.

un saludo
JLL

by **Ruben Fernandez** » Sat Nov 06, 2010 11:12 am

Hola JLL, gracias por la ayuda.

He visto que funciona con gmail, lo que necesito es tener una forma de enviar un archivo .txt o .prn como archivo adjunto o como cuerpo del mensaje,
que lo determinara el usuario del programa, quien debera llenar los datos de su cuenta.
No esta bien que le diga aun clilente que debe tener una cuenta de gmail para eso.

He usado Blat y pero no logro hacerlo andar en Windows 7, te agradezco me envies un ejemplo de uso que le das al Blat.

Muchas gracias y saludos

Ruben Fernandez

by **jll-fwh** » Sat Nov 06, 2010 8:06 pm

Hola Ruben:

CDOSYS tiene un parametro para el envio de adjuntos, el parametro es cAttach, pasale como parametro a mano la direccion de un archivo y veras como lo envia, en formato:

c:\carpeta\archivo.txt o tambien:

c:\archivos\archivo1.txt;c:\archivos\archivo2.txt

Respecto al BLAT te lo busco y te lo envio.

Sino te va bien, me dices tu e-amil y te envio el fuente PRG a tu cuenta.

No necesariamente tiene que tener tu cliente una cuenta gmail, puede ser cualquier servidor SMTP, yo solo lo he probado con gmail, pero no tiene porque dar problemas en otros. Voy a probar esta noche a cambiar la configuracion del programa y probare con SMTP de ono.com.

/*--------------------------------------------------------------------------------------------------------*/
STATIC Function FSendMail( cMailServer, cFrom, cTo, cSubject, cBody, cAttach, cBCC, cUser, cPass, nPort )
/*--------------------------------------------------------------------------------------------------------*/

// Funcion creada por Manuel Mercado en Febrero del 2009

Local oCfg, oMsg, oError, nEle, cToken, ;
aAttach := {}, ;
lAuth := ! Empty( cUser ) .and. ! Empty( cPass ), ;
nSendOpt := 2 // send using: 1 = pickup folder 2 = port

LOCAL lSendOk := .T.

Default nPort := 25, ;
cSubject := "", ;
cBody := ""

If "GMAIL.COM" $ Upper( cMailServer ) .and. ( Empty( cUser ) .or. Empty( cPass ) )
MsgStop( "Con GMail son requeridos nombre de usuario y contraseña", "Atención" )
Return Nil
EndIf

CursorWait()

nEle := 1

While ! Empty( cToken := StrToken( cAttach, nEle++, "," ) )
AAdd( aAttach, cToken )
EndDo

Try
oCfg := CreateObject( "CDO.Configuration" )

With Object oCfg:Fields
:Item( cdoSMTPServer ):Value := Trim( cMailServer )
:Item( cdoSMTPServerPort ):Value := nPort
:Item( cdoSendUsing ):Value := nSendOpt

If lAuth
:Item( cdoSMTPAuthenticate ):Value := 1
:Item( cdoSendUserName ):Value := Trim( cUser )
:Item( cdoSendPassword ):Value := Trim( cPass )
:Item( cdoSMTPUseSSL ):Value := 1
*:Item( cdoSMTPServer ):Value := ::cIp
*:Item( cdoSMTPServerPort ):Value := 587
*:Item( cdoSendUsing ):Value := 2 // cdoSendUsingPickup (1), cdoSendUsingPort (2), cdoSendUsingExchange (3)
*:Item( cdoSMTPAuthenticate ):Value := .T.
*:Item( cdoSMTPUseSSL ):Value := .F.
End

:Update()

End With

oMsg := CreateObject( "CDO.Message" )

With Object oMsg
:Configuration := oCfg
:From := Trim( cFrom )
:To := Trim( cTo )
:Subject := Trim( cSubject )
:TextBody := Trim( cBody )

For nEle := 1 To Len( aAttach )
:AddAttachment := AllTrim( aAttach[ nEle ] )
Next

If ! Empty( cBCC )
:BCC := Trim( cBCC )
EndIf

:Send()
End With

Catch oError
CursorArrow()
MsgStop( "No se pudo enviar el mensaje" + CRLF + "Error: " + cValToChar( oError:GenCode) + CRLF + ;
"SubC: " + cValToChar( oError:SubCode ) + CRLF + "OSCode: " + cValToChar( oError:OsCode ) + CRLF + ;
"SubSystem: " + cValToChar( oError:SubSystem ) + CRLF + "Mensaje: " + oError:Description )

oCfg := Nil
oMsg := Nil
Return( .F. )
End Try

oCfg := Nil
oMsg := Nil
CursorArrow()

Return( .T. )

by **Ruben Fernandez** » Sun Nov 07, 2010 11:35 am

JLL, Gracias, ya lo hice funcionar con emailer.

Con CDOSYS de Manuel Mercado cuando uso un archivo adjunto no lo manda, me da error, si funciona si no lo mando con attach...

Muchas gracias..
Igualmente Emailer funciona bien, la unica dificultad era encontar la forma que ejecutarlo desde FWH, cosa que ya salio bien, en el post
anterior indico como, por las dudas...

Saludos y MUCHA GRACIAS.

by **jll-fwh** » Sun Nov 07, 2010 6:25 pm

ok ruben.

lo unico que si usas un programa externo, no podras controlar si el correo se ha enviado correctamente no? o emailer crea algun fichero de control que indique que ha sido OK?

un saludo
JLL

by **Ruben Fernandez** » Mon Nov 08, 2010 5:02 pm

JLL averigue lo de Shellexecute, si retorna un valor entre 0 y 32 es porque hubo algun error, sino esta ok.

Hago el envio así: IF ShellExecute( 0, "open", "C:\Zonainmo\emailer.exe",envio2,,, ) <= 32
MsgInfo("Error")
else
MsgInfo("Correo enviado con éxito","Informe")
Endif

Saludos y Muchas gracias.

by **derpipu** » Tue Nov 09, 2010 3:49 pm

Hola a Todos, con el ejemplo del master Mercado, les da error al momento de adjuntar archivos si la ruta no esta completa, es decir deberia de ser:
c:\misistema\archivo.txt, y normalmente por lo menos yo usaba la ruta relativa, suponia que mi sistema ya sabia que yo estaba posicionado en c:\misistema\ y entonces solo le decia, enviar .\archivo.txt y aqui es donde genera el errror, solo pongan la ruta completa en el envio y veran que si funciona excelente el CDO

Saludos

FiveTech Software tech support forums

Linea de comandos con Emailer SOLUCIONADO

Linea de comandos con Emailer SOLUCIONADO

Re: Linea de comandos con Emailer

Re: Linea de comandos con Emailer

Re: Linea de comandos con Emailer SOLUCIONADO

Re: Linea de comandos con Emailer SOLUCIONADO

Re: Linea de comandos con Emailer SOLUCIONADO

Re: Linea de comandos con Emailer SOLUCIONADO

Re: Linea de comandos con Emailer SOLUCIONADO

Who is online