Folders in a folder

[driessen]

Hello,

The function "Directory()" reads the names and data of the files in a certain folder.

But how can we read the names of all the folders which can be found in a certain folder.

Thank you very much in advance.

[Enrico Maria Giordano]

Add "D" as the second parameter.

EMG

[James Bott]

Code: Select all  Expand view

/*
Purpose: Get list of folders (directories)
Author : James Bott, jbott@compuserve.com
Syntax : getFolders( <cPath> )
         cPath defaults to current directory
Returns: Array of directory names, or empty array if no directories exist
Bug    : A filename with no extension will be
         included as a directory even though it is not.

*/

#include "fivewin.ch"

//--- Test only
function main()

   local aFolders:= getFolders( "c:\" )
   local cString:= ""
   local i:=0

   for i=1 to len( aFolders )
      cString := cString + aFolders[i] + chr(10)
   next

   msgInfo( cString )

return nil
//--- end test



function getFolders( cPath )
   local aFiles := {}
   local aFolders:={}
   local i:=0

   default cPath:= ""

   cPath:= if( right(cPath,1)="\", cPath + "*.", cPath + "\*." )

   aFiles := directory( cPath, 'D' )

   // We start at 3 to eliminate the always present "." and ".." directories
   for i=3 to len(aFiles)
      aadd( aFolders, aFiles[i,1] )
   next

return aFolders

// EOF

[driessen]

James,
Enrico,

Thanks a lot for your answers.

I should have looked better to the syntax.

Sorry for disturbing you.

[RAMESHBABU]

Hello Mr.James,

Here I have a small workaround to avoid the bug you have mentioned in the Example.

Code: Select all  Expand view

#include "fivewin.ch"

//--- Test only
function main()

   local aFolders:= getFolders( "c:\" )
   local cString:= ""
   local i:=0

   for i=1 to len( aFolders )
      cString := cString + aFolders[i] + chr(10)
   next

   msgInfo( cString )

return nil
//--- end test

function getFolders( cPath )
   local aFiles := {}
   local aFolders:={}
   local i:=0
   local cOldPath := cPath                        // Added by RAMESH BABU P

   default cPath:= ""

   cPath:= if( right(cPath,1)="\", cPath + "*.", cPath + "\*." )

   aFiles := directory( cPath, 'D' )

   // We start at 3 to eliminate the always present "." and ".." directories
   for i=3 to len(aFiles)
       if IsDirectory(cOldPath+"\"+aFiles[i,1])   // Added by RAMESH BABU P
          aadd( aFolders, aFiles[i,1] )
       endif
   next

return aFolders

// EOF

Regards,

- Ramesh Babu P

[James Bott]

Good idea Ramesh. I wish I had thought of that.

Thanks,
James

[James Bott]

I cleaned up the code and fixed a problem with paths with trailing backslashes. This also has Ramesh's bug fix.

James

Code: Select all  Expand view

/*
Purpose: Get list of folders (directories)
Author : James Bott, jbott@compuserve.com

Syntax : getFolders( <cPath> )
         cPath defaults to current directory
Returns: Array of directory names, or empty array if no directories exist

Note: Thanks Ramesh for the bug fix!
*/

#include "fivewin.ch"

//--- Test only
function main()

   local aFolders:= getFolders( "c:\downloads" )
   local cString:= ""
   local i:=0

   for i=1 to len( aFolders )
      cString := cString + aFolders[i] + chr(10)
   next

   msgInfo( cString )

return nil
//--- end test

function getFolders( cPath )
   local aFiles := {}
   local aFolders:={}
   local i:=0

   default cPath:= ""
   cPath:= if( right(cPath,1)="\", cPath , cPath + "\" )

   aFiles := directory( cPath + "*.", 'D' )

   // We start at 3 to eliminate the always
   // present "." and ".." directories
   for i=3 to len(aFiles)
       if IsDirectory(cPath + aFiles[i,1]) // Added by RAMESH BABU P
          aadd( aFolders, aFiles[i,1] )
       endif
   next

return aFolders

// EOF