enviar correo desde prg

[QAZWSX2K]

saludos amigos, alguien tiene ya una rutina que funciones para enviar correo, estoy aburrido de estar probando con hb_sendmail(9, sendmail(), oEmailMsg:Send(), CreateObject( "CDO.Message" ) y ninguno funciona, gracias

[Carlos Mora]

Alex,
No puede ser que NINGUNO te funcione, algo debes estar haciendo mal, lo ideal seria que pongas algo de lo que has probado y que dices que te falla.
El tema es muy amplio y complejo, y cada vez más requiere de conocimientos en la materia para entender protocolos y demás.
No estarás tratando de usar hotmail, no?

Un saludo

[Armando]

Alex:

Lo ideal es que realices tus aplicaciones con tus propias herramientas, pero cuando
todo lo probado no funciona, tal vez sea bueno voltear la cara a otra herramienta.

http://www.afterlogic.com/mailbee/objects

Saludos

PD. No soy distribuidor, solo un simple usuario satisfecho.

[horacio]

Yo uso CDO y funciona perfectamente.

Saludos

[karinha]

Code: Select all  Expand view  RUN

#Include "FiveWin.ch"

// --- Envio de correo electronico
Function SendEmail(cFrom,cTo,cBCC,cAttach,cSubject,cBody,cUser,cPass)

   Local oDlg, aCtl[ 22 ], oFont
   //Local cMailServer := PadR( "smtp.gmail.com", 60 ) // servidor de correo
   Local cMailServer := PadR( "smtp.pleno.com.br", 60 ) // servidor de correo
   //local nPort:=465 // puerto usado por el servidor de correo
   local nPort:=587 // puerto usado por el servidor de correo
   local WS_3DLOOK:=4
   local CLR_HBROWN:=RGB( 205, 192, 176 )
   local CLR_NBLUE :=RGB( 142, 171, 194 )

   //default cFrom := PadR( "remitente@gmail.com", 60 ) // remitente
   default cFrom := PadR( "joao@pleno.com.br", 60 ) // remitente
   //default cTo := PadR( "destinatario@hotmail.com", 180 ) // destinatario (uno o varios separados con comas)
   default cTo := PadR( "joao@peno.com.br", 180 ) // destinatario (uno o varios separados con comas)

   default cBCC := Space( 180 ) // copias ocultas a (uno o varios separados con comas)
   default cAttach := Space(180) // archivo anexo (uno o varios separados con comas)
   default cSubject := Space( 60 ) // asunto
   default cBody := Space( 500 ) // cuerpo del mensaje
   default cUser := Space( 60 ) // nombre de usuario para autenticación
   default cPass := Space( 30 ) // contraseña para autenticación

   DEFINE FONT oFont NAME "Arial" SIZE 0, -16

   DEFINE DIALOG oDlg FROM 0, 0 TO 455, 703 PIXEL ;
      COLORS CLR_HBLUE, CLR_HBROWN ;
      TITLE "Envio de Mail" ;
      STYLE nOR( DS_MODALFRAME, WS_POPUP, WS_CAPTION, WS_SYSMENU, WS_3DLOOK )

   @ 10, 5 SAY    aCtl[ 1 ] PROMPT "Servidor de Correo" OF oDlg ;
      FONT oFont UPDATE ;
      COLORS CLR_HBLUE, CLR_HBROWN SIZE 70, 11 PIXEL

   @ 10, 80 GET    aCtl[ 2 ] VAR cMailServer OF oDlg ;
      FONT oFont UPDATE PICTURE "@K" ;
      COLORS CLR_HBLUE, CLR_WHITE SIZE 206, 11 READONLY PIXEL

   @ 10,294 SAY    aCtl[ 3 ] PROMPT "Puerto" OF oDlg ;
      FONT oFont UPDATE ;
      COLORS CLR_HBLUE, CLR_HBROWN SIZE 30, 11 PIXEL

   @ 10,320 GET    aCtl[ 4 ] VAR nPort OF oDlg ;
      FONT oFont UPDATE PICTURE "@K ####" ;
      COLORS CLR_HBLUE, CLR_WHITE SIZE 24, 11 READONLY PIXEL

   @ 24, 5 SAY    aCtl[ 5 ] PROMPT "Remitente" OF oDlg ;
      FONT oFont UPDATE ;
      COLORS CLR_HBLUE, CLR_HBROWN SIZE 70, 11 PIXEL

   @ 24, 80 GET    aCtl[ 6 ] VAR cFrom OF oDlg ;
      FONT oFont UPDATE PICTURE "@K" ;
      COLORS CLR_HBLUE, CLR_WHITE SIZE 264, 11 PIXEL

   @ 39, 5 SAY    aCtl[ 7 ] PROMPT "Destinatario" OF oDlg ;
      FONT oFont UPDATE ;
      COLORS CLR_HBLUE, CLR_HBROWN SIZE 70, 11 PIXEL

   @ 39, 80 GET    aCtl[ 8 ] VAR cTo OF oDlg ;
      FONT oFont UPDATE PICTURE "@K" ;
      COLORS CLR_HBLUE, CLR_WHITE SIZE 264, 11 PIXEL

   @ 54, 5 SAY    aCtl[ 9 ] PROMPT "Copia para" OF oDlg ;
      FONT oFont UPDATE ;
      COLORS CLR_HBLUE, CLR_HBROWN SIZE 70, 11 PIXEL

   @ 54, 80 GET    aCtl[ 10 ] VAR cBCC OF oDlg ;
      FONT oFont UPDATE PICTURE "@K" ;
      COLORS CLR_HBLUE, CLR_WHITE SIZE 264, 11 PIXEL

   @ 69, 5 SAY    aCtl[ 11 ] PROMPT "Adjuntar" OF oDlg ;
      FONT oFont UPDATE ;
      COLORS CLR_HBLUE, CLR_HBROWN SIZE 70, 11 PIXEL

   @ 69, 80 GET    aCtl[ 12 ] VAR cAttach OF oDlg PICTURE "@K" ;
      FONT oFont UPDATE ;
      COLORS CLR_HBLUE, CLR_WHITE SIZE 264, 11 PIXEL;
      // ACTION fAddAttach( aCtl[ 12 ] )

   @ 84, 5 SAY    aCtl[ 13 ] PROMPT "Asunto" OF oDlg ;
      FONT oFont UPDATE ;
      COLORS CLR_HBLUE, CLR_HBROWN SIZE 70, 11 PIXEL

   @ 84, 80 GET    aCtl[ 14 ] VAR cSubject OF oDlg ;
      FONT oFont UPDATE PICTURE "@K" ;
      COLORS CLR_HBLUE, CLR_WHITE SIZE 264, 11 PIXEL

   @ 99, 5 SAY    aCtl[ 15 ] PROMPT "Autenticación: Usuario" OF oDlg ;
      FONT oFont UPDATE ;
      COLORS CLR_HBLUE, CLR_HBROWN SIZE 80, 11 PIXEL

   @ 99, 87 GET    aCtl[ 16 ] VAR cUser OF oDlg ;
      FONT oFont UPDATE PICTURE "@K" ;
      COLORS CLR_HBLUE, CLR_WHITE SIZE 118, 11 PIXEL

   @ 99,213 SAY    aCtl[ 17 ] PROMPT "Contraseña" OF oDlg ;
      FONT oFont UPDATE ;
      COLORS CLR_HBLUE, CLR_HBROWN SIZE 44, 11 PIXEL

   @ 99,259 GET    aCtl[ 18 ] VAR cPass OF oDlg PASSWORD ;
      FONT oFont UPDATE PICTURE "@K";
      COLORS CLR_HBLUE, CLR_WHITE SIZE 85, 11 PIXEL

   @117.5,6 SAY    aCtl[ 19 ] PROMPT "Cuerpo del mensaje" OF oDlg ;
      SIZE 100, 11 PIXEL ;
      FONT oFont COLORS CLR_HBLUE, CLR_HBROWN

   @ 7,1.5 GET aCtl[ 20 ] VAR cBody OF oDlg ;
      FONT oFont MULTILINE UPDATE ;
      COLORS CLR_HBLUE, CLR_WHITE SIZE 42, 4.3

   @11.5,5 BUTTON aCtl[ 21 ] PROMPT "&Enviar" OF oDlg ;
      FONT oFont SIZE 53, 16 PIXEL ;
      ACTION fSendMail( cMailServer, cFrom, cTo, cSubject, cBody, cAttach, cBCC, cUser, cPass, nPort )

   @11.5,20 BUTTON aCtl[ 22 ] PROMPT "&Salir" OF oDlg ;
      FONT oFont SIZE 53, 16 PIXEL ACTION oDlg:End()

   ACTIVATE DIALOG oDlg CENTERED ;
      VALID ( oFont:End(), .T. )

Return Nil

// --- Enviar un mail
Function fSendMail( cMailServer, cFrom, cTo, cSubject, cBody, cAttach, cBCC, cUser, cPass, nPort )

   Local oCfg, oMsg, oError, nEle, cToken, bMens,;
   lAuth := ! Empty( cUser ) .and. ! Empty( cPass ), ;
   nSendOpt := 1 //2 // send using: 1 = pickup folder 2 = port

   memvar aAttach

   Default nPort := 25, ;
   cSubject := "", ;
   cBody := ""

   ? cMailServer, cFrom, cTo, cSubject, cBody, cAttach, cBCC, cUser, cPass, nPort

   if !IsInternet()

      //aviso({'ATENCION','No existe conección a internet','Intente más tarde o verifique su problema'})

      return .t.

   endif

   If "GMAIL.COM" $ Upper( cMailServer ) .and. ( Empty( cUser ) .or. Empty( cPass ) )
      MsgStop( "Con GMail son requeridos nombre de usuario y contraseña", "Atención" )
      Return .t.
   EndIf

   CursorWait()

   // bMens:=Mensaje('Para: '+cTo,'Espere, enviando un Mail')

   aAttach:={}

   if !Empty(cAttach)
      cAttach:='{"'+StrTran(cAttach,',','","')+'"}'
      aAttach:=cAttach
      aAttach:=&(aAttach)
   endif

   nEle := 1

   Try
      oCfg := CreateObject( "CDO.Configuration" )

      With Object oCfg:Fields
         :Item( cdoSMTPServer ):Value := Trim( cMailServer )
         :Item( cdoSMTPServerPort ):Value := nPort
         :Item( cdoSendUsing ):Value := nSendOpt

      If lAuth
         :Item( cdoSMTPAuthenticate ):Value := 1
         :Item( cdoSendUserName ):Value := Trim( cUser )
         :Item( cdoSendPassword ):Value := Trim( cPass )
         :Item( cdoSMTPUseSSL ):Value := 2 //1

      EndIf

      :Update()

   End With

   oMsg := CreateObject( "CDO.Message" )

   With Object oMsg
      :Configuration := oCfg
      :From := Trim( cFrom )
      :To := Trim( cTo )
      :Subject := Trim( cSubject )
      :TextBody := Trim( cBody )

      For nEle := 1 To Len( aAttach )
         :AddAttachment := AllTrim( aAttach[ nEle ] )
      Next

      If ! Empty( cBCC )
         :BCC := Trim( cBCC )
      EndIf

      :Send()

   End With

   Catch oError
      CursorArrow()
      // Eval(bMens)
      MsgStop( "No se pudo enviar el e-mail")
      oCfg := Nil
      oMsg := Nil
      Return .t.
   End Try

   oCfg := Nil
   oMsg := Nil
   SndPlaySound( GetWinDir() + "\media\Tada.wav", 0 )
   CursorArrow()

   Eval(bMens)

Return .t.
 



[QAZWSX2K]

nada ni con el ejemplo de carihna, debe haber algo mas que solo el codigo, no se una libreria, una dll o algo asi

da error 1001 (disp_e_membernotfoud) que en ninguna parte dice que es

[LuisPonce]

Hola

Yo envio emails desde prg con ayuda del CDOSYS

Code: Select all  Expand view  RUN

#include "FiveWin.ch"
#include "CdoSys.ch"

#define WS_3DLOOK  4
#define CLR_HBROWN nRGB( 205, 192, 176 )
#define CLR_NBLUE  nRGB( 142, 171, 194 )

//--------------------------------------------------------------------------------------------------------------------//

Function fEmail()

   Local oDlg, aCtl[ 22 ], oFont

   Local cMailServer := PadR( "smtp.gmail.com", 60 ), ;             // servidor de correo
         cFrom       := PadR( "remitente@gmail.com", 60 ), ;        // remitente
         cTo         := PadR( "destinatarios@hotmail.com", 180 ), ; // destinatario (uno o varios separados con comas)
         cBCC        := PadR( "destinatarios@hotmail.com", 180 ), ; // copias ocultas a (uno o varios separados con comas)
         cAttach     := PadR( "c:\fwh\bitmaps\fivewin.bmp", 180 ), ;// archivo anexo (uno o varios separados con comas)
         cSubject    := Space( 60 ), ;                              // asunto
         cBody       := Space( 500 ), ;                             // cuerpo del mensaje
         nPort       := 465, ;                                      // puerto usado por el servidor de correo
         cUser       := Space( 60 ), ;                              // nombre de usuario para autenticación
         cPass       := Space( 30 )                                 // contraseña para autenticación

   DEFINE FONT oFont NAME "Arial" SIZE 0, -16

   DEFINE DIALOG oDlg FROM 0, 0 TO 455, 703 PIXEL ;
          COLORS CLR_BLUE, CLR_HBROWN ;
          TITLE "CDOSYS Collaboration Data Objects for Windows 2000" ;
          STYLE nOR( DS_MODALFRAME, WS_POPUP, WS_CAPTION, WS_SYSMENU, WS_3DLOOK )

   @ 10,  5 SAY aCtl[ 1 ] PROMPT "Servidor de Correo:" OF oDlg ;
            FONT oFont UPDATE ;
            COLORS CLR_BLUE, CLR_HBROWN SIZE 70, 11 PIXEL

   @ 10, 80 GET aCtl[ 2 ] VAR cMailServer OF oDlg ;
            FONT oFont  UPDATE  PICTURE "@K" ;
            COLORS CLR_BLUE, CLR_WHITE SIZE 206, 11 PIXEL

   @ 10,294 SAY aCtl[ 3 ] PROMPT "Puerto:" OF oDlg ;
            FONT oFont UPDATE ;
            COLORS CLR_BLUE, CLR_HBROWN SIZE 30, 11 PIXEL

   @ 10,320 GET aCtl[ 4 ] VAR nPort OF oDlg ;
            FONT oFont  UPDATE  PICTURE "@K ####" ;
            COLORS CLR_BLUE, CLR_WHITE SIZE 24, 11 PIXEL

   @ 24,  5 SAY aCtl[ 5 ] PROMPT "Remitente:" OF oDlg ;
            FONT oFont UPDATE ;
            COLORS CLR_BLUE, CLR_HBROWN SIZE 70, 11 PIXEL

   @ 24, 80 GET aCtl[ 6 ] VAR cFrom OF oDlg ;
            FONT oFont  UPDATE  PICTURE "@K" ;
            COLORS CLR_BLUE, CLR_WHITE SIZE 264, 11 PIXEL

   @ 39,  5 SAY aCtl[ 7 ] PROMPT "Destinatario:" OF oDlg ;
            FONT oFont UPDATE ;
            COLORS CLR_BLUE, CLR_HBROWN SIZE 70, 11 PIXEL

   @ 39, 80 GET aCtl[ 8 ] VAR cTo OF oDlg ;
            FONT oFont  UPDATE  PICTURE "@K" ;
            COLORS CLR_BLUE, CLR_WHITE SIZE 264, 11 PIXEL

   @ 54,  5 SAY aCtl[ 9 ] PROMPT "Copia para:" OF oDlg ;
            FONT oFont UPDATE ;
            COLORS CLR_BLUE, CLR_HBROWN SIZE 70, 11 PIXEL

   @ 54, 80 GET aCtl[ 10 ] VAR cBCC OF oDlg ;
            FONT oFont  UPDATE  PICTURE "@K" ;
            COLORS CLR_BLUE, CLR_WHITE SIZE 264, 11 PIXEL

   @ 69,  5 SAY aCtl[ 11 ] PROMPT "Adjuntar:" OF oDlg ;
            FONT oFont UPDATE ;
            COLORS CLR_BLUE, CLR_HBROWN SIZE 70, 11 PIXEL

   @ 69, 80 GET aCtl[ 12 ] VAR cAttach OF oDlg  PICTURE "@K" ;
            FONT oFont  UPDATE ;
            COLORS CLR_BLUE, CLR_WHITE SIZE 253, 11 PIXEL // ACTION fAddAttach( aCtl[ 12 ] ) ; // descomentar para FWH 8.12 o posterior

   @ 69,333 BUTTON "..." OF oDlg SIZE 10, 10 PIXEL ACTION fAddAttach( aCtl[ 12 ] )

   @ 84,  5 SAY aCtl[ 13 ] PROMPT "Asunto:" OF oDlg ;
            FONT oFont UPDATE ;
            COLORS CLR_BLUE, CLR_HBROWN SIZE 70, 11 PIXEL

   @ 84, 80 GET aCtl[ 14 ] VAR cSubject OF oDlg ;
            FONT oFont  UPDATE PICTURE "@K" ;
            COLORS CLR_BLUE, CLR_WHITE SIZE 264, 11 PIXEL

   @ 99,  5 SAY aCtl[ 15 ] PROMPT "Autenticación: Usuario:" OF oDlg ;
            FONT oFont UPDATE ;
            COLORS CLR_BLUE, CLR_HBROWN SIZE 80, 11 PIXEL

   @ 99, 87 GET aCtl[ 16 ] VAR cUser OF oDlg ;
            FONT oFont  UPDATE PICTURE "@K" ;
            COLORS CLR_BLUE, CLR_WHITE SIZE 118, 11 PIXEL

   @ 99,213 SAY aCtl[ 17 ] PROMPT "Contraseña:" OF oDlg ;
            FONT oFont UPDATE ;
            COLORS CLR_BLUE, CLR_HBROWN SIZE 44, 11 PIXEL

   @ 99,259 GET aCtl[ 18 ] VAR cPass OF oDlg PASSWORD ;
            FONT oFont  UPDATE  PICTURE "@K";
            COLORS CLR_BLUE, CLR_WHITE SIZE 85, 11 PIXEL

   @118,  6 SAY aCtl[ 19 ] PROMPT "Cuerpo del mensaje" OF oDlg ;
            SIZE 100, 11 PIXEL ;
            FONT oFont COLORS CLR_BLUE, CLR_HBROWN

   @126, 10 GET aCtl[ 20 ] VAR cBody OF oDlg ;
            FONT oFont MULTILINE  UPDATE ;
            COLORS CLR_BLUE, CLR_WHITE SIZE 330, 72 PIXEL

   @208,213 BUTTON aCtl[ 21 ] PROMPT "&Enviar" OF oDlg ;
            FONT oFont SIZE 53, 16 PIXEL  ;
            ACTION fSendMail( cMailServer, cFrom, cTo, cSubject, cBody, cAttach, cBCC, cUser, cPass, nPort )

   @208,292 BUTTON aCtl[ 22 ] PROMPT "&Salir" OF oDlg ;
            FONT oFont SIZE 53, 16 PIXEL ACTION oDlg:End()

   ACTIVATE DIALOG oDlg CENTERED ;
            VALID ( oFont:End(), .T. )

Return Nil

//---------------------------------------------------------------------------------------------//

Function fSendMail( cMailServer, cFrom, cTo, cSubject, cBody, cAttach, cBCC, cUser, cPass, nPort )

   Local oCfg, oMsg, oError, nEle, cToken, ;
         aAttach  := {}, ;
         lAuth    := ! Empty( cUser ) .and. ! Empty( cPass ), ;
         nSendOpt := 2   // send using: 1 = pickup folder  2 = port

   Default nPort    := 25, ;
           cSubject := "", ;
           cBody    := ""

   If "GMAIL.COM" $ Upper( cMailServer ) .and. ( Empty( cUser ) .or. Empty( cPass ) )
      MsgStop( "Con GMail son requeridos nombre de usuario y contraseña", "Atención" )
      Return Nil
   EndIf

   CursorWait()

   nEle := 1

   While ! Empty( cToken := StrToken( cAttach, nEle++, "," ) )
      AAdd( aAttach, cToken )
   EndDo

   Try
      oCfg := CreateObject( "CDO.Configuration" )

      With Object oCfg:Fields
         :Item( cdoSMTPServer ):Value     := Trim( cMailServer )
         :Item( cdoSMTPServerPort ):Value := nPort
         :Item( cdoSendUsing ):Value      := nSendOpt

         If lAuth
            :Item( cdoSMTPAuthenticate ):Value := 1
            :Item( cdoSendUserName ):Value     := Trim( cUser )
            :Item( cdoSendPassword ):Value     := Trim( cPass )
            :Item( cdoSMTPUseSSL ):Value := 1
         EndIf

         :Update()
      End With


      oMsg := CreateObject( "CDO.Message" )

      With Object oMsg
         :Configuration := oCfg
         :From          := Trim( cFrom )
         :To            := Trim( cTo )
         :Subject       := Trim( cSubject )
         :TextBody      := Trim( cBody )

         For nEle := 1 To Len( aAttach )
            :AddAttachment := AllTrim( aAttach[ nEle ] )
         Next

         If ! Empty( cBCC )
            :BCC := Trim( cBCC )
         EndIf

         :Send()
      End With

   Catch oError
      CursorArrow()
      MsgStop( "No se pudo enviar el mensaje" + CRLF  + "Error: " + cValToChar( oError:GenCode) + CRLF + ;
               "SubC: " + cValToChar( oError:SubCode ) + CRLF + "OSCode: " + cValToChar( oError:OsCode ) + CRLF + ;
               "SubSystem: " + cValToChar( oError:SubSystem ) + CRLF + "Mensaje: " + oError:Description )

      oCfg := Nil
      oMsg := Nil
      Return Nil
   End Try

   oCfg := Nil
   oMsg := Nil
   SndPlaySound( GetWinDir() + "\media\Tada.wav", 0 )
   CursorArrow()

Return Nil

//---------------------------------------------------------------------------------------------//

Static Function fAddAttach( oGet )

   Local cFile, ;
         cAttach := oGet:VarGet()

   cFile := cGetFile( "*.*", "Selecciona el archivo" )

   If ! Empty( cFile )
      cAttach := Lower( PadR( AllTrim( cAttach ) + If( ! Empty( cAttach ), ",", "" ) + AllTrim( cFile ), 180 ) )
   EndIf

   oGet:cText( cAttach )

Return Nil


Condiciones de servicio de Google
 

Debes usar una cuenta de gmail, si funciona

Espero haberte ayudado

[Antonio Linares]

Luis,

Muchas gracias

[QAZWSX2K]

agradecido con todos pero como dije debe haber algo mas aparte de solo el codigo, lo mismo error 1001, DISP_E_MEMBERNOTFOUND

[Baxajaun]

Alex,

puedes publicar un pequeño ejemplo en el que de el error, quizás así te podamos ayudar.

Muchas gracias.

Saludos

[Baxajaun]

Alex,

mira en http://www.pctoledo.com.br/forum/viewtopic.php?f=4&t=10764&p=61999

Saludos

[FranciscoA]

Alex Wrote: da error 1001 (disp_e_membernotfoud) que en ninguna parte dice que es

Alex:
Deberias postear exactamente el codigo que estas usando.

Haciendo pruebas, una de las cosas que crea ese error es cuando se suministra el cAttach (cAdjuntos) incorrecto.

//cAdjuntos := "" //OK
//cAdjuntos := NIL //OK

// Path y nombres de ficheros deben ir correctos
cAdjuntos := CurDrive()+":\"+CurDir()+"\WCCIPQ" //en este caso, si WCCIPQ no existe, devuelve el error.

Error: 1001 SubC: 3 OSCode: 0 SubSystem: CDO.Message Mensaje: DISP_E_MEMBERNOTFOUND

Revisa si es lo anterior.
Saludos.

[FranciscoA]

Lo peor, en el caso que expuse anteriormente, es que no envía el correo, ni presenta mensaje de error.
Yo me dí cuenta porque la descripción del error la incorpora (no sé cómo y por qué), en el cAttach (cAdjuntos), que es un fichero de texto.
Saludos.

CORRIJO: El programa, al detectar algo ilegal, escribe en la bitacora, y como dije anteriormente: la descripción del error del email la incorpora (no sé cómo y por qué)

[FranciscoA]

viewtopic.php?f=6&t=31175&hilit=DISP_E_MEMBERNOTFOUND#p180409

http://forums.fivetechsupport.com/viewt ... ad#p177128

[hmpaquito]

Hola compañero,

DISP_E_MEMBERNOTFOUND es un error que se puede producir por multitud de circunstancias. Por ejemplo introduciendo mal el parametro pass de acceso a la cuenta. En general, al menos a mi, cuando me ha aparecido ese error ha sido por algun error mio en los parametros, por ejemplo el pass.

Serie bueno que probaras un ejemplo que funcione a algun compañero a falta de cambiar la cuenta y su pass.

saludos