Mover Botón de la barra de xbrowser

[jose_murugosa]

Buenos días a todos,
Una consulta sobre mover un botón en xbrowser.

Estoy usando xbrowser en algunos casos solo con las opciones de desplazamiento y generar excel.
Aquí un ejemplo de como lo hago:

Code: Select all | Expand

FUNCTION Main()
     LOCAL i
     
     REQUEST DBFCDX
     RddSetDefault( "DBFCDX" )
     set DATE FRENCH
     SET CENTURY ON
     SET EPOCH TO Year( Date() ) - 40

     USE C:\fwh\samples\customer NEW SHARED
     
     XBROWSER "CUSTOMER" TITLE "Prueba" SETUP ;
               ( oBrw:bInit :=  { |o|   ;
                    o:oWnd:oBar:aControls[ 8 ]:lGroup := .F., ;
                    o:oWnd:oBar:aControls[ 5 ]:Hide(), ;
                    o:oWnd:oBar:aControls[ 6 ]:Hide(), ;
                    o:oWnd:oBar:aControls[ 7 ]:Hide(), ;
                    o:oWnd:oBar:aControls[ 8 ]:Hide() } ;
                 )
RETURN nil

La pregunta es:
¿Cómo se puede hacer para que el botón de excel no aparezca distanciado de los demás que no se ocultaron?

[cnavarro]

Añade al codeblock o:oWnd:oBar:Refresh(), a ver

[jose_murugosa]

Cristóbal, gracias por tu respuesta y disculpa mi demora en contestar.
Si ya lo había probado pero no obtuve ningun resultado.

[karinha]

Esto?

Code: Select all | Expand

// C:\FWH\SAMPLES\MURUGOS.PRG

#include "FiveWin.ch"

REQUEST DBFCDX

FUNCTION Main()

   LOCAL i

   rddSetDefault( "DBFCDX" )

   SET DATE FRENCH
   SET CENTURY ON
   SET EPOCH TO Year( Date() ) - 40

   USE ..\SAMPLES\CUSTOMER NEW SHARED
   GO TOP

   XBROWSER "CUSTOMER" TITLE "Prueba" SETUP               ;
      ( oBrw:bInit :=  {| o |                             ;
        o:oWnd:oBar:aControls[ 8 ]:lGroup := .F.,         ;
        o:oWnd:oBar:aControls[ 5 ]:Hide(),                ;
        o:oWnd:oBar:aControls[ 6 ]:Hide(),                ;
        o:oWnd:oBar:aControls[ 7 ]:Hide(),                ;
        o:oWnd:oBar:aControls[ 8 ]:Hide(),                ;
        o:oWnd:oBar:Del( Len( o:oWnd:oBar:aControls ) ) } ; // aqui
      )


RETURN NIL

// FIN / END - kapiabafwh@gmail.com

Regards, saludos.

[karinha]

Maestro Navarro, ¿hay otra manera de hacer esto? Este es el único que conozco.

O esto?

Code: Select all | Expand

// C:\FWH\SAMPLES\MURUGOS.PRG - Version 2.

#include "FiveWin.ch"

REQUEST DBFCDX

FUNCTION Main()

   LOCAL i

   rddSetDefault( "DBFCDX" )

   SET DATE FRENCH
   SET CENTURY ON
   SET EPOCH TO Year( Date() ) - 40

   USE ..\SAMPLES\CUSTOMER NEW SHARED
   GO TOP

   /*
   XBROWSER "CUSTOMER" TITLE "Prueba" SETUP              ;
      ( oBrw:bInit :=  {| o |                            ;
        o:oWnd:oBar:aControls[ 8 ]:lGroup := .F.,        ;
        o:oWnd:oBar:aControls[ 5 ]:Hide(),               ;
        o:oWnd:oBar:aControls[ 6 ]:Hide(),               ;
        o:oWnd:oBar:aControls[ 7 ]:Hide(),               ;
        o:oWnd:oBar:aControls[ 8 ]:Hide(),               ;
        o:oWnd:oBar:Del( Len( o:oWnd:oBar:aControls )) } ;
      )
   */

   // Otro modelo
   XBROWSER "CUSTOMER" TITLE "Prueba" SETUP                              ;
      ( oBrw:bInit :=  {| o |                                            ;
        o:oWnd:oBar:aControls[ 8 ]:lGroup := .F.,                        ;
        o:oWnd:oBar:aControls[ 5 ]:Hide(),                               ;
        o:oWnd:oBar:aControls[ 6 ]:Hide(),                               ;
        o:oWnd:oBar:aControls[ 7 ]:Hide(),                               ;
        o:oWnd:oBar:aControls[ 8 ]:Hide(),                               ;
        o:oWnd:oBar:aControls[ 9 ]:Move( 0, o:oWnd:oBar:nWidth() -35 ) } ; // aqui
      )

RETURN NIL

// FIN / END - kapiabafwh@gmail.com

Regards, saludos.

[cnavarro]

Probad asi y decidme si os funciona ( a mi me funciona correctamente )

Code: Select all | Expand

#include "fivewin.ch"

FUNCTION Main()
     LOCAL i
     
     REQUEST DBFCDX
     RddSetDefault( "DBFCDX" )
     set DATE FRENCH
     SET CENTURY ON
     SET EPOCH TO Year( Date() ) - 40

     USE d:\fwh\fwhteam\samples\customer NEW SHARED
     
     XBROWSER "customer" TITLE "Prueba" SETUP ;
               ( oBrw:oWnd:bInit :=  { | o | ;
                    o:oBar:l2013 := .T., ;
                    o:oBar:l2010 := .F., ;
                    o:oBar:l2015 := .F., ;
                    o:oBar:aControls[ 5 ]:cTooltip  := o:oBar:aControls[ 9 ]:cToolTip, ;
                    o:oBar:aControls[ 5 ]:bAction   := o:oBar:aControls[ 9 ]:bAction, ;
                    o:oBar:aControls[ 5 ]:LoadBitmaps( FWBitmap( "Excel" ) ), ;
                    AEval( o:oBar:aControls, { | oBtt | oBtt:End() }, 6, 9 ), ; 
                    ASize( o:oBar:aControls, 5 ), ; 
                    AEval( o:oBar:aControls, { | oBtt | oBtt:Refresh() } ), ;
                    o:oBar:SetGradients(), ;
                    o:oBar:Refresh() ;
                  } )
RETURN nil

[karinha]

Excelente maestro Navarro. Prefiero LOOK 2007, pregunta: si quiero activar el botón XBROWSE() <Salir>, ¿cómo lo hago?

Code: Select all | Expand

// C:\FWH\SAMPLES\MURUGOS2.PRG

#Include "FiveWin.ch"

FUNCTION Main()

   LOCAL i

   REQUEST DBFCDX
   rddSetDefault( "DBFCDX" )

   SET DATE FRENCH
   SET CENTURY ON
   SET EPOCH TO Year( Date() ) - 40

   USE ..\SAMPLES\CUSTOMER NEW SHARED

   XBROWSER "CUSTOMER" TITLE "Prueba" SETUP                               ;
      ( oBrw:oWnd:bInit :=  {| o |                                        ;
        o:oBar:l2007 := .T.,                                              ;
        o:oBar:l2013 := .F.,                                              ;
        o:oBar:l2010 := .F.,                                              ;
        o:oBar:l2015 := .F.,                                              ;
        o:oBar:aControls[ 6 ]:Hide(),                                     ;
        o:oBar:aControls[ 7 ]:Hide(),                                     ;
        o:oBar:aControls[ 8 ]:Hide(),                                     ;
        o:oBar:aControls[ 9 ]:Hide(),                                     ;
        o:oBar:aControls[ 5 ]:cTooltip := o:oBar:aControls[ 9 ]:cToolTip, ;
        o:oBar:aControls[ 5 ]:bAction  := o:oBar:aControls[ 9 ]:bAction,  ;
        o:oBar:aControls[ 5 ]:LoadBitmaps( FWBitmap( "Excel" ) ),         ;
        AEval( o:oBar:aControls, {| oBtt | oBtt:End() }, 6, 9 ),          ;
        ASize( o:oBar:aControls, 5 ),                                     ;
        AEval( o:oBar:aControls, {| oBtt | oBtt:Refresh() } ),            ;
        o:oBar:SetGradients(),                                            ;
        o:oBar:Refresh()                                                  ;
      } )

RETURN NIL

// FIN / END

Regards, saludos.

[cnavarro]

Estimado Joao, luego intento hacerte un ejemplo, pero sería añadir al array aControls, ese boton con el tooltip "Salir" y el action oDlg:End()

[cnavarro]

Aqui tienes el ejemplo con el boton de "Cerrar"

Code: Select all | Expand

#include "fivewin.ch"

FUNCTION Main()
     LOCAL i
     
     REQUEST DBFCDX
     RddSetDefault( "DBFCDX" )
     set DATE FRENCH
     SET CENTURY ON
     SET EPOCH TO Year( Date() ) - 40

     USE c:\fwh\amples\customer NEW SHARED
     
     XBROWSER "customer" TITLE "Prueba" SETUP ;
               ( oBrw:oWnd:bInit :=  { | o | ;
                    o:oBar:l2013 := .T., ;
                    o:oBar:l2010 := .F., ;
                    o:oBar:l2015 := .F., ;
                    o:oBar:aControls[ 5 ]:cTooltip  := o:oBar:aControls[ 9 ]:cToolTip, ;
                    o:oBar:aControls[ 5 ]:bAction   := o:oBar:aControls[ 9 ]:bAction, ;
                    o:oBar:aControls[ 5 ]:LoadBitmaps( FWBitmap( "Excel" ) ), ;
                    o:oBar:aControls[ 6 ]:cTooltip  := "Exit", ;
                    o:oBar:aControls[ 6 ]:bAction   := { | oBtt | oBtt:oWnd:oWnd:End() }, ;
                    o:oBar:aControls[ 6 ]:LoadBitmaps( FWBitmap( "exit2" ) ), ;  // close16
                    o:oBar:aControls[ 6 ]:lRight    := .T., ;
                    AEval( o:oBar:aControls, { | oBtt | oBtt:End() }, 7, 9 ), ; 
                    ASize( o:oBar:aControls, 6 ), ; 
                    AEval( o:oBar:aControls, { | oBtt | oBtt:Refresh() } ), ;
                    o:oBar:SetGradients(), ;
                    o:oBar:Refresh() ;
                  } )
RETURN nil

[karinha]

Excelente maestro Navarro. Gracias, tks.

Regards, saludos.

[jose_murugosa]

Cristóbal, Joao:
Muuchas gracias.
Recien puedo ver y probar el código.
Que buenas soluciones las dos Cristóbal, me decanté por la del botón de salir.
Una belleza.

Gracias por la buena disposición que muestran siempre para ayudar.
Un fuerte abrazo