IP, Mac Address, Name desde mi modem

[FranciscoA]

Aqui podemos ver el resultado de lo que estoy haciendo, y lo que consigo con el codigo de Daniel.
https://ibb.co/bPQsrMZ

[sysctrl2]

Buen trabajo, felicidades !

[FranciscoA]

Aqui está con las modif de César y Danielmaximiliano

Code: Select all  Expand view

#include "FiveWin.ch"

FUNCTION Main()    //Probando()
  local aDispConect := {}, cDir := TrueName(".\")
  local cTexto, n, nLineas, cLinea, cIP, cMac, cNombre, cIpInterfaz, cFabricante

  WAITRUN( "cmd.exe /c  arp -a > " +cDir+ "\ARP.txt" , .f.)
  //WaitRun("Notepad.exe " +cDir+ "\ARP.txt")

  cTexto  := MEMOREAD(cDir + "\ARP.txt")
  nLineas := MLCOUNT(cTexto)

  //Agreg dispositivo desde donde se corre el programa. El .txt solo presenta la IP
  cLinea      := MEMOLINE(cTexto,255,2)  //en linea 2 esta la ip del equipo desde donde se corre
  cIpInterfaz := SUBSTR(cLinea,11,12)
  WsaStartUp()
  cNombre := GetHostName()
  WsaCleanUp()  

  cMac        := MacAddrHost()
  cFabricante := Fabricante(AllTrim(STRTRAN(cMac,'-','')))  

  AAdd( aDispConect, { cIpInterfaz, cMac, cNombre, cFabricante} )
  //Fin Agreg dispositivo desde donde se corre el programa

  For n := 4 To nLineas      //En lin 4 del .txt comienzan las ip y mac
     cLinea  := MEMOLINE(cTexto,255,n)
     cIP     := SUBSTR(cLinea,3,20)
     cMac    := SUBSTR(cLinea,25,21)  
     WsaStartUp()
     cNombre := GetHostByAddress(AllTrim(cIP))  //Obtiene nombre a partir de la IP  
     WsaCleanUp()
     cNombre := if(empty(cNombre),AllTrim(cIP),cNombre)      
     cFabricante := Fabricante(AllTrim(STRTRAN(cMac,'-','')))    

     if Substr(AllTrim(cIP),1,9) == Substr(AllTrim(cIpInterfaz),1,9) .and. AllTrim(cMac) <> "ff-ff-ff-ff-ff-ff"
        AAdd( aDispConect, { cIP, cMac, cNombre ,cFabricante} )
     endif
  Next

  SysRefresh()

  XBROWSER aDispConect TITLE "Dispositivos Conectados" ;
     SETUP ( oBrw:cHeaders := {"IP", "MAC", "DISPOSITIVO","FABRICANTE"} )

 RETURN NIL

STATIC FUNCTION Fabricante(cMac)  //Cesar (cmsof)
LOCAL cText, i , cResult
cText := WebPageContents('https://aruljohn.com/mac/'+cMac)
cResult := SUBSTR(cText,At('<tr><td>Vendor</td><td><span id="vdr14999879">',cText)+46,200 )    
cResult := LEFT(cResult,At('</span>',cResult)-1)
RETURN cResult


//Codigo de Danielmaximiliano
// memberlist.php?mode=viewprofile&u=2388
//----------------------------------------------//
STATIC function MacAddrHost()
local oCollection1, oCollection2, obj1, obj2
local nInd := 1, IPAddress, MACAddress, aInfo := {}
local oLoc := CreateObject( "wbemScripting.SwbemLocator" )
local oWMI := oLoc:ConnectServer()

    oCollection1 := oWMI:ExecQuery( "SELECT * FROM Win32_NetworkAdapter WHERE Manufacturer != 'Microsoft' AND NOT PNPDeviceID LIKE 'ROOT\\%'" )
    oCollection2 := oWMI:ExecQuery( 'SELECT * from Win32_NetworkAdapterConfiguration where IPEnabled=TRUE' )
    For Each obj1 In oCollection1
        For Each obj2 In oCollection2
            IPAddress   := obj2:IPAddress(0)  
            MACAddress  := obj2:MACAddress(0)
            aadd( aInfo,{ IPAddress, MACAddress } )
        Next
    Next
 
    RELEASE oLoc, oWMI

return Alltrim( aInfo[1,2] )

[cmsoft]

Muy buen trabajo Francisco!
Gracias por compartirlo!!!

[Danielmaximiliano]

gracias Daniel!

Hola Antonio y a todos los integrantes del foro.
en mis tiempos libres miro el foro y como este post todavia no tiene final sigo viendo una resolución al mismo
viendo que ARP -a devuelve en algunos casos no toda la informacion ya que en casa con la Notebook solo devuelve mi Notebook y
el TVSmart con conexion cableada, en el caso que use el Wifi de la Notebook devuelve todas las conexiónes (Address Resolution Protocol)
buscando informacion sobre ARP encontre https://github.com/QbsuranAlang/arp-scan-windows-/tree/main un utilitario para CMD que es para
x86 y x64 y devuelve una informacion completa y simple, como se puede recompilar con Visual Studio 17 mi pregunta es.....
¿ se puede convetir a .LIB o .DDL en vez de .EXE y si es posible redirecciónar a un archivo .CVS o devolver a una variable ?
si descargan desde el sitio el .zip dentro estan los .EXE para probar desde CMD, la linea de comando es asi
arp-scan -t 192.168.1.1/50 > ip.txt

PD: no se como se sube una imagen aqui

[Antonio Linares]

> PD: no se como se sube una imagen aqui

Puedes crear un repositorio gratuito en github, subir allí tus imágenes y aqui copias la URL de la imagen en tu repo en github

[Danielmaximiliano]

César, muy bien!

Como bien dices, solo falta obtener la MAC del equipo anfitrión, y los nombres de los demás dispositivos que no son computadoras.

Continuaremos investigando.

Saludos.

Hola Francisco :
para obtener el nombre de equipo con cmd

C:\Users\danie>nbtstat -n

Avast SecureLine VPN:
Dirección IP del nodo: [0.0.0.0] Id. de ámbito : []

No hay nombres en la caché

Ethernet:
Dirección IP del nodo: [192.168.1.40] Id. de ámbito : []

Tabla de nombres locales NetBIOS

Nombre Tipo Estado
---------------------------------------------
DANIEL <20> Único Registrado
DANIEL <00> Único Registrado
WORKGROUP <00> Grupo Registrado

Wi-Fi:
Dirección IP del nodo: [0.0.0.0] Id. de ámbito : []

No hay nombres en la caché

no se puede obtener nombres si no pertenecen a una red, en este caso el router es solo una puerta de enlace hacia internet enmascarando la ip local con la ip publica del modem
por ello no se puede obtener el nombre mediante NBTSTAT -A iplocal para obtener su nombre.. SLDS