Quitar o mostrar button action de un get

[leandro]

Hola buenas tardes para todos, tengo una pregunta, quiero poder quitar o mostrar en tiempo de ejecución, ese button que aparece al lado del GET, nosotros lo usamos para abrir un dialogo de búsquedas.

Que propiedad me permite quitarlo o ponerlo?



Espero haberme hecho entender de antemano gracias.

[JoseAlvarez]

Hola leandro,

Mientras contestan los gurus, se me ocurre que puedes usar dos controles get. Uno con el action y otro sin. Muestras uno y ocultas el otro segun la necesidad.

[karinha]

Leandro, no entiendo por qué quieres ocultar el botón GET. ¿Por qué no usa un botón EN EL LADO de GET y lo habilita/deshabilita según sea necesario o usa Hide()/Show() según sea necesario?

Regards, saludos.

[leandro]

Gracias Jose y karinha por las sugerencias... así lo tenemos, pero esa es la solución con "efectos especiales" jejejejeje, nos gustaría, si se puede, poder ocular o mostrar ese botón a conveniencia.

[karinha]

Estimado Leandro, asi es Simples. Mira se sirve:

Code: Select all  Expand view  RUN

// C:\FWH\SAMPLES\LEANDGET.PRG - By Kapiaba.

#Include "FiveWin.ch"

FUNCTION Main()

   LOCAL oDlg, oBtn, oBtn2, oFont, oBold, oSay
   LOCAL oGet1, oGet2, oGet3, oGet4, oGet5
   LOCAL cVar1, cVar2, cVar3, cVar4

   cVar1 := 0
   cVar2 := 0
   cVar3 := 50000.00
   cVar4 := 0

   SkinButtons()

   DEFINE FONT oFont NAME 'Tahoma' SIZE 0, -16 BOLD
   DEFINE FONT oBold NAME 'Tahoma' SIZE 0, -14 BOLD

   DEFINE DIALOG oDlg TITLE "Quitar o mostrar button action de un get" PIXEL ;
      SIZE 320, 300 TRANSPARENT COLOR METRO_EMERALD, CLR_WHITE FONT oBold

   oDlg:lHelpIcon := .F.

   @ 56,10 SAY oSay PROMPT "José Alvares, ¡seguro que lo haces mejor!"       ;
      FONT oBold SIZE 155, 20 PIXEL OF oDlg TRANSPARENT UPDATE               ;
      COLORS METRO_ORANGE, CLR_WHITE

   @ 10, 10 GET oGet1 VAR cVar1 bitmap "..\bitmaps\on.bmp" ;
      ACTION( msginfo( "With Transparent" ) ) OF oDlg PIXEL SIZE 60, 12

   oGet1:lBtnTransparent := .T.       // transparent button get oGet1

   @ 40, 10 GET oGet2 VAR cVar2 bitmap "..\bitmaps\on.bmp" ;
      ACTION( msginfo( "Without Transparent" ) ) of oDlg PIXEL SIZE 60, 12

   // CON IMAGEN AL INICIO - SHOW() AL INICIO.
   @ 70, 10 GET oGet3 VAR cVar3 bitmap "..\bitmaps\chkyes.bmp" OF oDlg       ;
      PIXEL SIZE 120, 12 ACTION( msginfo( "With Adjust-Transparent" ) )

   oGet3:lAdjustBtn      := .T.
   oGet3:nClrTextDis     := CLR_WHITE // Color text disable status
   oGet3:nClrPaneDis     := CLR_BLUE  // Color Pane disable status

   // SIN IMAGEN - HIDE() AL INICIO.
   @ 70, 10 GET oGet4 VAR cVar3 OF oDlg PIXEL SIZE 120, 12

   oGet4:lDisColors      := .F.       // Deactive disable color
   oGet4:nClrTextDis     := CLR_WHITE // Color text disable status
   oGet4:nClrPaneDis     := CLR_BLUE  // Color Pane disable status

   @ 100, 10 GET oGet5 VAR cVar4 bitmap "..\bitmaps\chkyes.bmp" OF oDlg      ;
      PIXEL SIZE 120, 12 ACTION( msginfo( "With Adjust-Transparent" ) )

   oGet5:lAdjustBtn      := .T.
   oGet5:nClrTextDis     := CLR_WHITE // Color text disable status
   oGet5:nClrPaneDis     := CLR_BLUE  // Color Pane disable status

   @ 130, 10 BTNBMP oBtn PROMPT "Con Image" CENTER SIZE 50, 14 PIXEL OF oDlg  ;
      NOROUND 2007 FONT oFont                                                 ;
      ACTION( CON_IMAGE_IN_GET( oBtn, oGet3, oGet4, oDlg ) )

   @ 130, 80 BTNBMP oBtn2 PROMPT "Sin Image" CENTER SIZE 50, 14 PIXEL OF oDlg ;
      NOROUND 2007 FONT oFont                                                 ;
      ACTION( SIN_IMAGE_IN_GET( oBtn2, oGet3, oGet4, oDlg ) )

   ACTIVATE DIALOG oDlg CENTERED ON INIT( oGet4:Hide() )

    oFont:End()
    oBold:End()

RETURN NIL

FUNCTION CON_IMAGE_IN_GET( oBtn, oGet3, oGet4, oDlg )

   oGet4:Hide()

   oDlg:Update()

   oGet3:Show()

   oDlg:Update()

   // oBtn:Disable()
   // oBtn:Refresh()

RETURN( .T. )

FUNCTION SIN_IMAGE_IN_GET( oBtn2, oGet3, oGet4, oDlg )

   oGet3:Hide()

   oDlg:Update()

   oGet4:Show()

   oDlg:Update()

   // oBtn2:Disable()
   // oBtn2:Refresh()

RETURN( .T. )

// FIN / END - kapiabafwh@gmail.com
 

Regards, saludos.

[cmsoft]

Puedes hacerlo asi
oGet:oBtn:Show() o oGet:oBtn:Hide()

Code: Select all  Expand view  RUN

#include "FiveWin.ch"
FUNCTION Main()
Local oDlg, oBot, oGet, nVar := 1
DEFINE DIALOG oDlg TITLE "Ocultar boton" FROM 05,15 TO 40,70
@ 05,05 GET oGet VAR nVar PICTURE "999999" right OF oDlg ACTION(MsgInfo("Accion"))
@ 20,05 BUTTON oBot PROMPT "Ocultar" SIZE 30,12 OF oDlg PIXEL ACTION oGet:oBtn:Hide()
@ 20,55 BUTTON oBot PROMPT "Mostrar" SIZE 30,12 OF oDlg PIXEL ACTION oGet:oBtn:Show()
ACTIVATE DIALOG oDlg CENTERED
RETURN nil

[leandro]

Excelente Cesar muchas gracias como siempre por la ayuda. Es exactamente lo que queríamos hacer.

[karinha]

Excelente César. Gracias.

https://forums.fivetechsupport.com/viewtopic.php?f=3&t=42830&start=0

Regards, saludos.