FiveTech Software tech support forums

Code: Select all  Expand view

  REDEFINE XBROWSE oBrwP ID BRW_XBRW OF oDlg AUTOSORT  ;
            COLUMNS "RazSocial", "CUIT" ;
            HEADERS "RazSocial", "CUIT" ;
            OBJECT  ::oQVProv
 

Code: Select all  Expand view

oQryPrv:= hA:oConn:Query( "SELECT * FROM provclie WHERE id_prvcli="+cIDProv )
oQryPrv:nombre := "IDEAS & DESARROLLOS" // O como se llame el campo donde grabas el nombre del proveedor
oQryPrv:Save()
 

Code: Select all  Expand view

#include "fivewin.ch"
#include "XBROWSE.ch"
#include "Tdolphin.ch"
function Mario_test()

   local  oDlg, oBrw, oBot, oGet, base,cSql, oServer, oQry, oError

   CONNECT oServer HOST "localhost" ;
                      USER "root" ;
                      PASSWORD "" ;
                      PORT 3306;
                      FLAGS 0;
                      DATABASE "test"
   
   TEXT INTO cSql
   CREATE TABLE IF NOT EXISTS `datos` (
  `NOMBRE` VARCHAR(35) NOT NULL,
  `CODIGO` INT(10) NOT  NULL AUTO_INCREMENT,
  PRIMARY KEY (`CODIGO`)
   ) ENGINE=INNODB AUTO_INCREMENT=1 DEFAULT CHARSET=utf8
   ENDTEXT
   oServer:Execute(cSql)
   oServer:Execute("INSERT INTO datos (nombre) VALUES (' ')")
   oQry:= oServer:Query("SELECT * FROM datos ")  

   DEFINE DIALOG oDlg TITLE "Prueba browse " FROM 09,15 TO 28,135
   oDlg:lHelpIcon := .f.

   @ 02,080 XBROWSE oBrw DATASOURCE oQry SIZE 325,120 OF oDlg PIXEL ;
       COLUMNS "codigo","nombre" HEADERS "Codigo","Nombre";
       SIZES   100,400 AUTOSORT
   @ 00,00 SAY oBrw:oSeek PROMPT "" OF oDlg PIXEL
   oBrw:CreateFromCode()
 

   @10,423 BUTTON oBot PROMPT "&Salir" OF oDlg SIZE 30,10 ACTION oDlg:End() PIXEL

   ACTIVATE DIALOG oDlg CENTER
   base:=oQry:GetRowObj()
   DEFINE DIALOG oDlg TITLE "Prueba Get " FROM 09,15 TO 28,135
   oDlg:lHelpIcon := .f.

   @ 02,080 GET oGet VAR base:nombre SIZE 300,12 OF oDlg PIXEL

   @10,423 BUTTON oBot PROMPT "&Salir" OF oDlg SIZE 30,10 ACTION oDlg:End() PIXEL
   // Activo el dialog
   ACTIVATE DIALOG oDlg CENTER

   oQry:oRow := base
   TRY
    oServer:BeginTransaction()
    oQry:Save()
    oQry:Refresh(.t.)
    oServer:CommitTransaction()
   CATCH oError
     MsgInfo("Error")
   
   END TRY

return nil

MarioG wrote:Muchas gracias Nicanor
No sabia de esto: Set_MyLang( "es_ES" ) // Seleccionar el idioma en MYSQl

Code: Select all  Expand view

 HB_LANGSELECT( 'ESWIN' )
 HB_SetCodePage("ESWIN")
 HB_CDPSELECT("ESWIN")
 

MarioG wrote:Gracias!

Me esta pasando un tema que hace rato no lo puedo solucionar, y tiene que ver con datos en Tablas
Escribo en una variable, por ej., "Ideas & Desarrollos"
Luego el SAY me muestra "Ideas _Desarrollos"
He probado con varias funciones, como por ej. HB_Str2UTF8(), u otras y no le encuentro la solución
Por eso intenté probar Set_MyLang()

Pruebo y comento...

Code: Select all  Expand view

#include "fivewin.ch"

function Main()

   local oWnd, oSay, cText

   cText    := "IDEAS & DESARROLLOS"

   DEFINE window oWnd
   @ 30,50 SAY oSay PROMPT cText SIZE 200,20 PIXEL OF oWnd
   ACTIVATE WINDOW oWnd CENTERED

return nil
 

Code: Select all  Expand view

#include "fivewin.ch"

#define SS_NOPREFIX         0x00000080

function Main()

   local oWnd, oSay, cText

   cText    := "IDEAS & DESARROLLOS"

   DEFINE window oWnd
   @ 30,50 SAY oSay PROMPT cText SIZE 200,20 PIXEL OF oWnd
   oSay:WinStyle( SS_NOPREFIX, .t. )  // inserted
   ACTIVATE WINDOW oWnd CENTERED

return nil