¿Cómo saber cuanta memoria ocupa mi aplicación?

[AngelSalom]

Hola amigos, como ando peleado con los recursos, liberación de memoria, etc, etc,etc ... me vendría genial saber cuánto memoria está utilizando mi aplicación (desde la misma aplicación, claro).
¿Alguna función que me informe de esto?

Gracias!

[Biel EA6DD]

Code: Select all | Expand

FUNCTION Main()
    ?  WorkingSetPrivate() 
RETURN NIL

//-----------------------------------------------------------------------------
FUNCTION WorkingSetPrivate(cName)
   /*Biel Maimo 2016*/
   LOCAL oLocator,oWmi,oList, oProc
   LOCAL aList:={}
   IF cName==NIL
      cName := SubStr(hb_ProgName(),Len( cFilePath( HB_ProgName() ))+1)
      cName := Left(cName,Len(cName)-4)
   ENDIF
   //--
   oLocator   := CreateObject( "wbemScripting.SwbemLocator" )
   oWMI       := oLocator:ConnectServer()
   oList      := oWmi:ExecQuery( "select * from Win32_PerfRawData_PerfProc_Process  WHERE name='"+cName+"'")
   FOR EACH  oProc IN oList
      AAdd( aList, { oProc:Name,oProc:WorkingSetPrivate} )
   NEXT
RETURN Val(aList[1,2]) / 1024

 

[AngelSalom]

Magnífico Biel, justo lo que necesitaba.

[karinha]

Biel, cual és el comando equivalente en xHarbour de hb_ProgName()? Gracias, saludos.

[Biel EA6DD]

Biel, cual és el comando equivalente en xHarbour de hb_ProgName()? Gracias, saludos.

Puedes probar hb_ArgV() que creo que existe en xHarbour, o ExeName().
En cualquier caso puedes llamar la función pasandole como parametro el nombre de tu programa.

[karinha]

Gracias Biel, perfecto.

Code: Select all | Expand

#include "FiveWin.ch"

FUNCTION Main()

    ?  WorkingSetPrivate()

RETURN NIL

//-----------------------------------------------------------------------------
FUNCTION WorkingSetPrivate(cName)
   /*Biel Maimo 2016*/
   LOCAL oLocator,oWmi,oList, oProc
   LOCAL aList:={}
   IF cName==NIL

      #IFDEF __XHARBOUR__  // Qual e o equivalente em xHarbour?

         cName := SubStr(HB_ARGV( 0 ),Len( cFilePath( HB_ARGV( 0 ) ))+1)
         cName := Left(cName,Len(cName)-4)

      #ELSE

         cName := SubStr(hb_ProgName(),Len( cFilePath( HB_ProgName() ))+1)
         cName := Left(cName,Len(cName)-4)

      #ENDIF

   ENDIF
   //--
   oLocator   := CreateObject( "wbemScripting.SwbemLocator" )
   oWMI       := oLocator:ConnectServer()
   oList      := oWmi:ExecQuery( "select * from Win32_PerfRawData_PerfProc_Process  WHERE name='"+cName+"'")
   FOR EACH  oProc IN oList
      AAdd( aList, { oProc:Name,oProc:WorkingSetPrivate} )
   NEXT
RETURN Val(aList[1,2]) / 1024
 



[karinha]

Biel, una duda: el resultado és en: Bytes, Mega Bytes? Ó Giga Bytes? gracias, saludos.

[Biel EA6DD]

Biel, una duda: el resultado és en: Bytes, Mega Bytes? Ó Giga Bytes? gracias, saludos.

El resultado se expresa en KB, pero puedes ajustar el retorno a la unidad que desees, simplemente cambiando divisior.

Code: Select all | Expand

...
Val(aList[1,2]) / 1024 // 
 

[juan_arroyo_t]

oList := oWmi:ExecQuery( "select * from Win32_PerfRawData_PerfProc_Process WHERE name='"+cName+"'")

Por favor

Como puedo utilizar este codigo si uso dbf's ?

Muchas gracias

[cnavarro]

Eso no tiene nada que ver con el RDD que utilices

[juan_arroyo_t]

Muchas gracias Cristobal

Funciona perfecto

Saludos