Seleccion multiple automatica xBrowse

[JoseAlvarez]

Saludos estimados amigos del foro.

Tengo un xBrowse con los 12 meses del año.

Necesito que al ingresar un dato numerico desde un get, por ejemplo 6, se seleccionen en el xBrowse las filas desde enero a junio.

Se que debe ser algo muy simple, pero no encuentro como hacerlo.

Gracias adelantadas por la Ayuda !!

[nageswaragunupudi]

Code: Select all  Expand view  RUN

function SelMonths1()

   local oDlg, oFont, oBrw
   local aData := Array( 12, 2 )
   local nMth  := 0

   AEval( aData, { |a,i| a[ 1 ] := NTOCMONTH( i ), a[ 2 ] := hb_RandomInt( 1000,9999 ) }  )

   DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
   DEFINE DIALOG oDlg SIZE 300,400 PIXEL TRUEPIXEL FONT oFont
   @ 20,20 SAY "Months :" GET nMth PICTURE "99" SIZE 100,24 PIXEL OF oDlg RIGHT ;
      VALID ( If( nMth < 0 .or. nMth > 12, .f., ( ;
         oBrw:aSelected := Array( nMth ), ;
         AEval( oBrw:aSelected, { |u,i| oBrw:aSelected[ i ] := i } ), ;
         oBrw:Refresh(), oBrw:SetFocus(), .t. ) ) )

   @ 50,20 XBROWSE oBrw SIZE -20,-20 PIXEL OF oDlg ;
      DATASOURCE aData AUTOCOLS LINES NOBORDER FOOTERS

   WITH OBJECT oBrw
      :nStretchCol   := 1
      :SetMultiSelectCol()
      :CreateFromCode()
   END

   ACTIVATE DIALOG oDlg CENTERED
   RELEASE FONT oFont

return nil

 

[nageswaragunupudi]

2nd alternative

Code: Select all  Expand view  RUN

function SelMonths2()

   local oDlg, oFont, oBrw
   local aData := Array( 12, 2 )
   local nMth  := 0

   AEval( aData, { |a,i| a[ 1 ] := NTOCMONTH( i ), a[ 2 ] := hb_RandomInt( 1000,9999 ) }  )

   DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
   DEFINE DIALOG oDlg SIZE 300,400 PIXEL TRUEPIXEL FONT oFont
   @ 20,20 SAY "Months :" GET nMth PICTURE "99" SIZE 100,24 PIXEL OF oDlg RIGHT ;
      VALID ( If( nMth < 0 .or. nMth > 12, .f., ( ;
         oBrw:aSelected := Array( nMth ), ;
         AEval( oBrw:aSelected, { |u,i| oBrw:aSelected[ i ] := i } ), ;
         oBrw:Refresh(), oBrw:SetFocus(), .t. ) ) )

   @ 50,20 XBROWSE oBrw SIZE -20,-20 PIXEL OF oDlg ;
      DATASOURCE aData AUTOCOLS LINES NOBORDER FOOTERS

   WITH OBJECT oBrw
      :nStretchCol   := 1
      :nMarqueeStyle := 6
      :CreateFromCode()
   END

   ACTIVATE DIALOG oDlg CENTERED
   RELEASE FONT oFont

return nil
 

[JoseAlvarez]

Thansk a lot mr Rao.

Working perfect !