XBrowse: how to keep the selected row position

[Enrico Maria Giordano]

In this sample, try to press the down arrow and then ESC. The new dialog doesn't keep the position of the selected row but moves it to the top.

Is there a way to keep the selected row position?

Code: Select all  Expand view

#include "Fivewin.ch"


FUNCTION MAIN()

    USE CUSTOMER

    TEST()

    TEST()

    RETURN NIL


STATIC FUNCTION TEST()

    LOCAL oDlg, oBrw

    DEFINE DIALOG oDlg;
           SIZE 800, 600

    @ 0, 0 XBROWSE oBrw

    oBrw:CreateFromCode()

    ACTIVATE DIALOG oDlg;
             ON INIT oDlg:SetControl( oBrw );
             CENTER

    RETURN NIL

EMG

[cnavarro]

Try with this

Code: Select all  Expand view

#include "Fivewin.ch"

Static nRowPos := 1

FUNCTION MAIN()

    USE CUSTOMER

    TEST()

    TEST()

    RETURN NIL


STATIC FUNCTION TEST()

    LOCAL oDlg, oBrw

    DEFINE DIALOG oDlg;
           SIZE 800, 600

    @ 0, 0 XBROWSE oBrw

    oBrw:CreateFromCode()
    oBrw:Keyno( nRowPos )

    ACTIVATE DIALOG oDlg;
             ON INIT oDlg:SetControl( oBrw );
             CENTER
    nRowPos  := oBrw:KeyNo

    RETURN NIL

 

[Enrico Maria Giordano]

Thank you Cristobal, unfortunately your sample works exactly like mine. Did you try it? Am I missing something?

EMG

[cnavarro]

Try with this code, or use METHODS SaveState/RestoreState

Code: Select all  Expand view

Static nRowPos := 1
Static nRowSel := 1

FUNCTION MAIN()

    USE CUSTOMER

    TEST()

    TEST()

    RETURN NIL


STATIC FUNCTION TEST()

    LOCAL oDlg, oBrw

    DEFINE DIALOG oDlg;
           SIZE 800, 600

    @ 0, 0 XBROWSE oBrw

    oBrw:CreateFromCode()
    oBrw:Keyno( nRowPos )
    oBrw:nRowSel := nRowSel
    oBrw:Refresh()


    ACTIVATE DIALOG oDlg;
             ON INIT oDlg:SetControl( oBrw );
             CENTER
    nRowPos  := oBrw:KeyNo
    nRowSel  := oBrw:nRowSel

    RETURN NIL

 

[Enrico Maria Giordano]

It seems to work, thank you.

EMG

[Enrico Maria Giordano]

Simplified code:

Code: Select all  Expand view

#include "Fivewin.ch"


FUNCTION MAIN()

    USE CUSTOMER

    TEST()

    TEST()

    RETURN NIL


STATIC FUNCTION TEST()

    LOCAL oDlg, oBrw

    STATIC nRowSel := 1

    DEFINE DIALOG oDlg;
           SIZE 800, 600

    @ 0, 0 XBROWSE oBrw

    oBrw:CreateFromCode()

    oBrw:nRowSel = nRowSel

    ACTIVATE DIALOG oDlg;
             ON INIT oDlg:SetControl( oBrw );
             CENTER

    nRowSel = oBrw:nRowSel

    RETURN NIL

EMG