Alguien hizo funcionar FiveWeb con Dolphin

[cmsoft]

Estimados. La pregunta es esa. Incluso si alguien lo hizo funcionar con dbfs? Ya que los ejemplos que descargue no funcionan. Hay uno que dice Otto que es un ejemplo que abre y usa dbfs y tampoco me funciono.
Si alguien ha hecho alguna prueba exitosa de conexion con dolphin, agradecere cualquier informacion
Gracias de antemano

[Antonio Linares]

Todos los ejemplos que nosotros implementamos usaban DBFs

Busca en todos los PRGs de ejemplos por DBF

[cmsoft]

Hola Antonio:
Mi pregunta es por el post http://forums.fivetechsupport.com/viewtopic.php?f=6&t=26154&start=0&hilit=dolphin+y+fiveweb que publicaste hace un tiempo, y como hay algunos ejemplos de ello en los samples, y me interesaria hacer algun desarrollo al respecto, por eso lo pregunto.
También intenté ejecutar el ejemplo de Otto (otto.prg) pero me da error tambien. (Ese es con DBFs).
Quería por eso, saber si era posible unir las dos herramientas (Dolphin + FiveWeb) ya que uso Dolphin con mis aplicaciones de escritorio con muy buenos resultados y deseaba seguir con esa estructura.
Mas puntualmente, mi pregunta apuntaba a si era posible, o definitivamente tendría que pensar en otra alternativa para Web+MySql.
Gracias de antemano por tu respuesta Antonio. Saludos cordiales.!

[Antonio Linares]

Si, Dolphin se puede usar perfectamente como indico en ese post. El error que da se debe a que ha debido cambiar algo en la configuración del servidor, pues yo uso un servidor compartido.

Fijate en el código fuente mio y adapatalo a tu conexión y debe funcionarte sin problemas

[cmsoft]

Gracias Antonio por tu pronta respuesta!!
He probado con localhost (para conectarme a mi base de datos) y a otra que tengo acceso remoto, pero no he podido.
Pero si se puede, sigo haciendo pruebas!
Comento los resultados!!

[cmsoft]

Anda en localhost!!!!! Gracias Antonio!!!
Voy a probarlo remoto y sigo comentando!!!
Estoy Felizzzz!!!

[Antonio Linares]

Muy bien

A ver si asi más y más usuarios se dan cuenta de la potencia de FiveWeb y se animan a usarlo

[albeiroval]

cmsoft,

porfavor puedes poner el codigo que te funciono ?

saludos,

albeiro

[cmsoft]

Aca va, es el ejemplo MyApp1.prg pero lo arregle para localhost con tablas que yo tengo

Code: Select all  Expand view

#include "FiveWeb.ch"

//----------------------------------------------------------------------------//

function Main( cParams )

   local aParams := If( cParams != nil, hb_aTokens( cParams, ":" ), nil )
   local cParam := If( aParams != nil, aParams[ 1 ], "" )

   SET BACKIMAGE TO "http://fiveweb.googlecode.com/svn/trunk/images/citynight.jpg"
   
   SetTheme( "base" )
   
   do case
      case cParam == "login"
           CheckLogin( aParams )

      case cParam == "users"
           Users()

      case cParam == "clients"
           Clients()

      otherwise
           Login()

  endcase

return nil

//----------------------------------------------------------------------------//

function Login()

   local oDlg, oImg, oBot
   local oGetName, cUserName := Space( 30 )
   local oGetPass, cPassword := ""

   DEFINE DIALOG oDlg TITLE "Login" SIZE 650, 400

   @  30,  30 IMAGE oImg FILENAME "../images/user.png" SIZE 120, 120 OF oDlg

   @  69, 190 SAY "User" SIZE 110, 40 OF oDlg

   @ 124, 190 SAY "Password" SIZE 110, 40 OF oDlg

   @  66, 315 GET oGetName VAR cUserName SIZE 300, 40 OF oDlg

   @ 124, 315 GET oGetPass VAR cPassword SIZE 300, 40 OF oDlg PASSWORD

   @ 265, 189 BUTTON oBot PROMPT "Ok" SIZE 110, 40 OF oDlg ;
      ACTION ( "document.location = '" + AppName() + "?login:' + " ) + ;
             'oGetName.value + ":" + oGetPass.value'

   @ 265, 335 BUTTON oBot PROMPT "Cancel" SIZE 110, 40 OF oDlg ;
      ACTION ( oDlg:End() ) // Executed in the server in advance

   ACTIVATE DIALOG oDlg NOWAIT

return nil

//----------------------------------------------------------------------------//

function CheckLogin( aParams )

   // ? aParams[ 2 ]  username
   // ? aParams[ 3 ]  password
   
   BuildMenu()

return nil

//----------------------------------------------------------------------------//

function BuildMenu()

   local oMenu
   
   MENU oMenu
      MENUITEM "About"
      MENU
         MENUITEM "This app..." ;
            ACTION MsgAbout( "My FiveWeb app", "(c) FiveTech Software" )
      ENDMENU
     
      MENUITEM "Files"
      MENU
         MENUITEM "Users" ;
            ACTION ( 'document.location = "' + AppName() + '?users"' )
           
         MENUITEM "Clients" ;
            ACTION ( 'document.location = "' + AppName() + '?clients"' )
      ENDMENU
     
      MENUITEM "Operations"
      MENUITEM "Help"
   ENDMENU
   
return oMenu

//----------------------------------------------------------------------------//

function Users()

   local oDlg, oServer, oBrw
   
   BuildMenu()
   
   oServer = TDolphinSrv():New( "localhost", "root", "" )

   if oServer:hMySQL == nil
      MsgInfo( "can't connect to the database" )
      return nil
   endif
         
   oServer:SelectDB( "bases" )
   
   DEFINE DIALOG oDlg TITLE "Users" SIZE 1000, 600
   
   @ 10, 10 BROWSE oBrw SIZE 900, 100 OF oDlg ;
      ARRAY oServer:Query( "SELECT * FROM usuarios LIMIT 0, 30" )
   
   ACTIVATE DIALOG oDlg NOWAIT
   
   oServer:End()
   
return nil  

//----------------------------------------------------------------------------//

function Clients()

   local oDlg, oServer, oBrw
   
   BuildMenu()
   
   oServer = TDolphinSrv():New( "localhost", "root", "" )

   if oServer:hMySQL == nil
      MsgInfo( "can't connect to the database" )
      return nil
   endif
         
   oServer:SelectDB( "bases" )
   
   DEFINE DIALOG oDlg TITLE "Clients" SIZE 1200, 650
   
   @ 5, 2 BROWSE oBrw SIZE 1150, 100 OF oDlg ;
      ARRAY oServer:Query( "SELECT * FROM gastos LIMIT 0, 1000" )
   
   ACTIVATE DIALOG oDlg NOWAIT
   
   oServer:End()
   
return nil  

//----------------------------------------------------------------------------//  

Tengo una base de datos llamada "bases" y abro una query de la tabla usuarios y otra de gastos y los muestro en el browse. Sencillo pero lo importante que levanta la base de datos.
Lo probé en una base de datos remota y funciono bien tambien, aunque el MyApp2.exe estaba en mi host.
Para eso instalé xampp y levante el servicio en mi pc.
Espero te sirva.
Saludos

[albeiroval]

Gracias cmsoft,

pruebo y te comento.

[cmsoft]

Antonio:
Hay alguna manera de poder mostrar el contenido de las variables almacenadas en memoria en FiveWeb?
Ya que al declarar una variable STATIC (en mi caso cUsuario) y querer usarla despues, no me funciona

Code: Select all  Expand view

function CheckLogin( aParams )

   // ? aParams[ 2 ]  username
   // ? aParams[ 3 ]  password
   local oServer, oQry
 
   oServer = TDolphinSrv():New( "localhost", "root", "" )

   if oServer:hMySQL == nil
      MsgInfo( "Perdon, pero la conexion no esta disponible" )
      return nil
   endif
         
   oServer:SelectDB( "bases" )
   oQry := oServer:Query( "SELECT * FROM usuarios WHERE usuario = '" +;
                           ALLTRIM(aParams[2]) + "' AND clave = '" + ALLTRIM(aParams[3]) + "'" )
   IF oQry:nRecCount > 0
      cUsuario := oQry:usuario
      BuildMenu()
      ELSE
      MsgInfo("Error, usuario no valido")
      Main()      
   ENDIF  
   
   oServer:End()  

return nil

Luego si quiero mostrar esa variable en un MsgInfo o en un MsgAbout no me la muestra, y no muestra nada.

Code: Select all  Expand view

MENUITEM "This app..." ;
            ACTION MsgAbout( "My FiveWeb app", "Usuario:"+cUsuario )

El proceso lo probé y si pongo un usuario y clave erroneo no accede
Gracias de antemano Antonio

[Antonio Linares]

Tienes que entender que el EXE en el servidor devuelve unos valores y luego termina, acaba, ya no hay ni variables ni nada.

Un vez entiendes esto, ya no te equivocas al intentar acceder a algo que ya no existe.

Piénsalo un poco, porque esto es la clave de entender su funcionamiento

[sysctrl2]

Hola Antonio,
Fiveweb funciona en una Tablet con Android ?

necesito levantar pedidos en una Tablet,

código producto
descripción
Cantidad
Precio Unitario
Importe
*******************************

Saludos..

[mlaffont]

Amigos, estoy haciendo algunas pruebas con Fiveweb, viendo que con la clase Tdolphin se puede conectar a MySql, esta misma clase permite conectarme a SQL Server ?, como puedo conseguir algun ejemplo de conexión a SQL Server ?

Saludos

[cmsoft]

Dolphin te permite conectar a MySql, no a Sql Server, podrías con Ado pero no se si funciona para FiveWeb, eso lo tendría que responder Antonio!
Saludos