Calcular Ultimo dia del Mes

[jbrita]

Amigos una consulta, si tengo el mes y el año como puedo armar una fecha pero que me ponga e ultimo dia del ese periodo por ejemplo

03-2015 SERIA 31-03-2015
02-2015 SERIA 28-02-2015

eso,gracias

[ACC69]

Amigos una consulta, si tengo el mes y el año como puedo armar una fecha pero que me ponga e ultimo dia del ese periodo por ejemplo

03-2015 SERIA 31-03-2015
02-2015 SERIA 28-02-2015

eso,gracias

Ejemplo:

TitRp := "Reporte auxiliar de cuentas " +(F_DMA(,,VAL(SUBS(cMA_Fin,1,2)),.F.,'MA',.T.,VAL(SUBS(cMA_Fin,3,2))))

Code: Select all  Expand view

//------------------------------------------------------------------------------
 * FUNCIONES DE FECHAS Y VALIDACION *****
//------------------------------------------------------------------------------
FUNCTION F_DMA(X,Y,FECHAf,FMDAf,FORMAf,ULTDMf,ANOf)
 Local UltD_Mes, UDM, dForm
 Local DIAm := { 'Domingo','Lunes','Martes','Miercoles','Jueves','Viernes',;
                'Sabado' ;
               }
 Local MESm := { 'Enero','Febrero','Marzo','Abril','Mayo','Junio','Julio',;
                'Agosto','Septiembre','Octubre','Noviembre','Diciembre'  ;
               }

 Local DIAn := If( FMDAf = .T.,If( DAY(FECHAf) <=9,'0'+STR(DAY(FECHAf),1 ) ,;
                                                       STR(DAY(FECHAf),2)),.F.)
 Local DIAf := If( FMDAf = .T.,     Dow(FECHAf),.F. )
 Local MESf := If( FMDAf = .T.,   Month(FECHAf),.F. )
 Local ANOn := If( FMDAf = .T.,Str(Year(FECHAf),4),.F. )

 If ULTDMf <> NIL
     ULTD_MES:= ctod('01/'+Str(FECHAf)+'/'+Str(ANOf,4))
     ULTD_MES:= ULTD_MES + 27

     Do While month(ULTD_MES) = FECHAf
         UDM := day(ULTD_MES)
         ++ULTD_MES
     EndDo
 EndIf

 Do Case
    Case FORMAf=='DFMA' // FORMATO: Viernes 01 de Enero de 1999
          * EJ--> F_DMA(10,12,DATE(),.T.,'FMA')      // 01/ENE/99
          dForm := DIAm[DIAf] +' '+ DIAn +' de '+ MESm[MESf] +' de '+ ANOn

    Case FORMAf=='FMA'  // FORMATO: 01/ENE/1999
          * EJ--> F_DMA(10,12,DATE(),.T.,'FMA')      // 01/ENE/99
          dForm := If( MESf>0,DIAn+'/'+UPPER(SUBSTR(MESm[MESf],1,3))+'/'+ANOn,'')

    Case FORMAf=='MES'  // FORMATO: enero
          * EJ--> F_DMA(10,12,MES,.F.,'MES')         // ENERO CON NUMERICO
          * EJ--> F_DMA(10,12,MONTH(FHA),.F.,'MES')  // ENERO CON CTOD()
          * FORMATO: F_DMA(10,12,MES,.F.,'MES',,,'3C')  // ENE EXTRAE 3 CARACTERES
          dForm := lower(MESm[FECHAf])

    Case FORMAf=='MA'   // 31/enero/2001
          * EJ--> F_DMA(,,MES,.F.,'MA',.T.,ANO)
          dForm := Ltrim(STR(UDM))+'/'+MESm[FECHAf]+'/'+Ltrim(Str(ANOf))

    Case FORMAf=='MA2'   // enero 2001
          * EJ--> F_DMA(,,MES,.F.,'MA',.T.,ANO)
          dForm := MESm[FECHAf]+' '+Ltrim(str(ANOf))

    Case FORMAf=='UDMA' // FORMATO: 31 de Enero de 1999.
          * EJ--> F_DMA(,,MES,.F.,'UDMA',.T.,ANO))
          dForm := Ltrim(Str(UDM)) +' de '+ MESm[FECHAf]+' de '+Ltrim(Str(YEAR(ANOf),4))

 EndCase
RETURN (dForm)

Saludos y buen dia Jbrita

[hmpaquito]

Code: Select all  Expand view

FUNCTION UltimoDiaMes(nMes, nAno)
Local d
d:= CToD("01/"+ Str(If(nMes == 12, 01, nMes+ 1), 2)+ "/"+ Str(If(nMes == 12, nAno+ 1, nAno), 2)  // Primer dia del mes siguiente
d--  // Dia ultimo del mes anterior
RETURN d
 

[acuellar]

Jbrita

Utiliza ésta función DaysInMonth(nMes) te retorna el último día del mes.

Code: Select all  Expand view

?DaysInMonth(Month(date()))
 

Saludos,

Adhemar

[jrestojeda]

Hola,

Todos los meses a excepción de febrero tienen una cantidad de días ya definida.
Yo lo hago así:

dFecha es una fecha cualquiera. A partir de esa fecha la función devuelve el última día del mes.

Code: Select all  Expand view

Function EOM(dFecha)

A:=MONTH(dFecha)

B2:=STRZERO(A,2)
B3:=STRZERO(YEAR(dFecha),4)

DO CASE
   CASE A = 1
      B1:="31"
   CASE A = 2
      FecSig:=CTOD("01/03/"+STRZERO(YEAR(dFecha),4)) - 1
      B1:=STRZERO(DAY(FecSig),2)
   CASE A = 3
      B1:="31"
   CASE A = 4
      B1:="30"
   CASE A = 5
      B1:="31"
   CASE A = 6
      B1:="30"
   CASE A = 7
      B1:="31"
   CASE A = 8
      B1:="31"
   CASE A = 9
      B1:="30"
   CASE A = 10
      B1:="31"
   CASE A = 11
      B1:="30"
   CASE A = 12
      B1:="31"
ENDCASE

dFecha:=CTOD(B1+"/"+B2+"/"+B3)

Return dFecha
//

Espero te sirva la idea.
Saludos,

[jnavas]

FUNCTION FCHFINMES(dFinMes)
dFinMes:=(dFinMes-Day(dFinMes))+35
RETURN dFinMes-Day(dFinMes)

[karinha]

Code: Select all  Expand view

FUNCTION UltimoDiaMes(nMes, nAno)
Local d
d:= CToD("01/"+ Str(If(nMes == 12, 01, nMes+ 1), 2)+ "/"+ Str(If(nMes == 12, nAno+ 1, nAno), 2)  // Primer dia del mes siguiente
d--  // Dia ultimo del mes anterior
RETURN d
 

Code: Select all  Expand view

#include "FiveWin.ch"

FUNCTION Main()

  LOCAL nMes, nAno

  PRIV D

  SET DATE BRITISH
  SET EPOCH TO 1950
  SET CENTURY ON

  nMes := 03
  nAno := 2015

  D := UltimoDiaMes(nMes, nAno)

  ? D  // Retorna: 31/03/2000 ???

RETURN NIL

FUNCTION UltimoDiaMes(nMes, nAno)

   Local d

   d:= CToD("01/"+ Str(If(nMes == 12, 01, nMes+ 1), 2)+ "/"+ Str(If(nMes == 12, nAno+ 1, nAno), 2) )  // Primer dia del mes siguiente
   d--  // Dia ultimo del mes anterior

RETURN d
 



[jnavas]

FUNCTION FCHFINMES(dFinMes)
dFinMes:=(dFinMes-Day(dFinMes))+35
RETURN dFinMes-Day(dFinMes)

FUNCTION FCHINIMES(dIniMes)
dIniMes:= EVAL(oDp:bFecha,dIniMes)
RETURN (dIniMes-Day(dIniMes))+1

[acuellar]

No se porque quieren descubrir la pólvora si existe la función: nDia:=DaysInMonth(nMes)

Saludos,

Adhemar

[Armando]

Amigos:

Y en xHarbour existe esta otra función

Code: Select all  Expand view

EoM( [<dDate>] ) --> dLastDayOfMonth
 

Saludos

[jbrita]

Muchisimas Gracias a todos.

Saludos

[FranciscoA]

Hola, llego tarde, pero... por si la quieren usar.

Code: Select all  Expand view

//------------------------//Devuelve fecha con ultimo dia del mes-año digitado
Function DiaUltMes(dFecha)
local dUltDia:=dFecha
While month(dUltDia)=month(dFecha)
   dUltDia+=1
enddo
Return dUltDia-1
 

Saludos

[noe aburto]

facil....

// --- Regresa el ultimo dia del mes
function UltimoDia(dFecha,lFecha)
local dFecPiv:=dFecha

default lFecha:=.f.
while month(dFecPiv)==month(dFecha)
dFecPiv++
end
return if(lFecha,dFecPiv-1,day(dFecPiv-1))

[jnavas]

Amigos:

Y en xHarbour existe esta otra función

Code: Select all  Expand view

EoM( [<dDate>] ) --> dLastDayOfMonth
 

Saludos

Armando,
Gracias, cuando cree estas funciones no existia harbour, gracias por la información. Esta funcion es estandar de harbour?

[Armando]

Amigos:

Pues parece que cada uno quiere lucir lo mejor de su código, pero como dice
Ademar, están descubriendo el agua caliente,

Juan:
Es función de xHarbour, aún no utilizo Harbour al 100%

Saludos