TREE

[Flavio Zago]

Saudações a todos.

Esta é minha primeira participação neste forum, e espero poder
contar com a ajuda dos colegas e também poder ajudar quando
meus conhecimentos assim o permitirem.

No momento gostaria de saber se é possível a partir de um Objeto Menu ( oMenu )
já criado, gerar um outro Objeto Tree ( oTree ).

Obrigado.
Flavio
FWH 14.04 - xHarbour - Bcc582 - Pelles
Araras, SP, Brasil.

[Antonio Linares]

Flavio,

Bienvenido a estos foros

Aqui tienes una función que hace lo que quieres, a ver si te sirve:

Code: Select all  Expand view

function MenuTree( oMenu )

   local oDlg
   
   DEFINE DIALOG oDlg SIZE 200, 300
   
   ACTIVATE DIALOG oDlg CENTERED ;
      ON INIT AddItems( oMenu:aMenuItems, TTreeView():New( 1, 2, oDlg,,,,, 180, 250 ) )

return nil

function AddItems( aItems, oItem )

   AEval( aItems, { | oMenuItem, oIt | oIt := oItem:Add( oMenuItem:cPrompt ),;
                If( ValType( oMenuItem:bAction ) == "O",;
                AddItems( oMenuItem:bAction:aItems, oIt ),) } )
   
return nil      

Desde tu programa haz MenuTree( oWnd:oMenu )

[Flavio Zago]

Antonio Linares,

É isso mesmo que estou precisando, só fiquei com uma
dúvida:

Como faço para a função retornar o Objeto oTree?

Obrigado.

[Antonio Linares]

Code: Select all  Expand view

function MenuTree( oMenu )

   local oDlg, oTree
   
   DEFINE DIALOG oDlg SIZE 200, 300
   
   ACTIVATE DIALOG oDlg CENTERED ;
      ON INIT AddItems( oMenu:aMenuItems, oTree := TTreeView():New( 1, 2, oDlg,,,,, 180, 250 ) )

return oTree

function AddItems( aItems, oItem )

   AEval( aItems, { | oMenuItem, oIt | oIt := oItem:Add( oMenuItem:cPrompt ),;
                If( ValType( oMenuItem:bAction ) == "O",;
                AddItems( oMenuItem:bAction:aItems, oIt ),) } )
   
return nil      

[Flavio Zago]

Funcionou perfeitamente.

Muito obrigado