Lineas Adicionales al Final de REPORT

[JoseAlvarez]

Hola amigos, Feliz fin de Semana a todos.

Tengo Elaborado un reporte de presupuestos con la clase REPORT
Necesito agregar al final del informe algunas lineas adicionales como por ejemplo:

"Este presupuesto tiene una validez de 8 dias"
"Los precios aqui reflejados NO incluyen el IVA y son para compras de contado"
"Los equipos eléctricos tienen una garantía máxima de 15 días"

y cualquier otra que sea necesaria.

Seguramente es muy fácil hacerlo, pero no he dado con la manera.

Acá dejo el código:

Code: Select all  Expand view

REPORT oReport TITLE '' LEFT                                                                       ;
       HEADER _cCompanyName                                                                      , +;
       'R.i.f. '+pad(_cCompanyRif,83)                                                     , +;
       _cDireccion1                                                                       , +;
       _cDireccion2                                                                       , +;
       'Ciudad.: '+PAD(alltrim(_cCiudad),30)       + Spac(30)+'Cliente...: '+cGetCliente  , +;
       'C.O.D..: '+PAD(alltrim(_cCodigo_postal),6) + Spac(54)+'R.I.F.....: '+cGetRif      , +;
       'Estado.: '+PAD(alltrim(_cEstado,20))       + Spac(60)+'Telf......: '+cTelfCliente , +;
       'Telf...: '+PAD(_cTelefonos,55)             + spac(5) +'Dirección.: '+cDirCliente1 , +;  
       'Correo.: '+PAD(_cMail     ,55)             + spac(17)               +cDirCliente2 , +;
       'WebSite: '+PAD(_cWebSite  ,55)                                                    , +;
       'Moneda.: '+PAD(alltrim(_Nombre_Moneda)+' ('+alltrim(_cSigno_Moneda)+')',27)         +;
       'Presupuesto No.:'+pad(cGetNumeroDoc,11)+ ' Fecha: '+dToc(date())        +;
                                 Spac(2)+' Hora: '+Time()                                                 +;
                                 Spac(12)+"Página.: "+alltrim(Transform(oReport:nPage,"999"))              ;
       left FONT oFontColumn, oFontTitle, oFontColumnB                                       ;
       PREVIEW
       COLUMN TITLE "Descripción"  DATA _aFacturas[nI, 2] Left                           FONT 1
       COLUMN TITLE "Presentación" DATA _aFacturas[nI,18] Left                           FONT 1
       COLUMN TITLE "Cantidad"     DATA _aFacturas[nI, 9] Center picture _cPictMaskAncla FONT 1
       COLUMN TITLE "Precio"       DATA _aFacturas[nI,10] Center picture _cPictMaskAncla FONT 3  //shadow
       COLUMN TITLE "SubTotal"     DATA _aFacturas[nI,15] Center picture _cPictMaskAncla FONT 1  TOTAL

     if oReport:lCreated
          oReport:cGrandTotal:=PAD('Son: '+Fnct_MontoEscrito(nGet_SubtotalAncla,1),101)+ ' Total '+ alltrim(_cSigno_Moneda)      //97
          oReport:settxtcolor(CLR_BLACK,0)
          oReport:nTotalLine:=1
          oReport:nTitleUpLine:=1
          oReport:nTitleDnLine:=1
          oReport:bWhile:={|| nI <= nHasta }
          oReport:oHeader:aFont[1]:={||2}  
          oReport:oHeader:aFont[2]:={||3}  
          oReport:oTitle :aFont[1]:={||3}
          oReport:bSkip := { | | nI++}
      endif

END REPORT

ACTIVATE REPORT oReport

 

[cmsoft]

Code: Select all  Expand view

ACTIVATE REPORT oRep WHILE !oQry:EOF()  ;
             ON STARTPAGE oRep:SayBitmap(.1,.1,"LOGO.BMP",.5,.5);
             ON POSTGROUP oRep:EndPage();
             ON POSTEND Mifuncion(oRep)

STATIC FUNCTION MiFuncion(oRep)
oRep:NewLine()
oRep:Say(3,"Este presupuesto tiene una validez de 8 dias")
oRep:EndLine()
RETURN nil
 

[JoseAlvarez]

Hola César, como estas?

Excelente, a la primera, todo bien.

Me ahorraste mi proxima consulta. Quiero imprimir el logo de la empresa en el encabezado del reporte, ya vi esto que colocaste alli:

ON STARTPAGE oRep:SayBitmap(.1,.1,"LOGO.BMP",.5,.5)

ahora mi duda es: ¿se comporta igual en todas las impresoras sin importar su resolucion? y en caso de que no sea asi, como se corregiría ese detalle?

[cmsoft]

Hola José:
¿se comporta igual en todas las impresoras sin importar su resolucion?
Si, report se adapta según la impresoras donde elijas imprimir