SCROLL INSIDE XBROWSE LINES WITH MEMO

[nnicanor]

I have an xbrowse with memos with different lines numbers, i need to adjust lines to size or scroll into xbrowse line if line numbers greater than 3 lines.

Regards,

[nageswaragunupudi]

Code: Select all  Expand view

#include "fivewin.ch"

REQUEST DBFCDX

function Main()

   local oDlg, oBrw, oFont

   USE WWONDERS VIA "DBFCDX"

   DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
   DEFINE DIALOG oDlg SIZE 500,600 PIXEL TRUEPIXEL FONT oFont

   @ 20,20 XBROWSE oBrw SIZE -20,-20 PIXEL OF oDlg ;
      DATASOURCE "WWONDERS" ;
      COLUMNS "NAME", "DETAILS" ;
      COLSIZES 200 ;
      CELL LINES NOBORDER

   WITH OBJECT oBrw
      :nDataLines       := 4
      WITH OBJECT :aCols[ 2 ]
         :nEditType     := EDIT_GET
         :bClrEdit      := { || { CLR_BLACK, CLR_YELLOW } }
         // If we do not want user to modify and save changes
         :bOnPreEdit    := { |o| o:oEditGet:lReadOnly := .t. }
      END
      :CreateFromCode()
   END

   ACTIVATE DIALOG oDlg CENTERED
   RELEASE FONT oFont

return nil
 

[Silvio.Falconi]

If we do want user to modify and save changes ?
that is, if we wanted to edit on line ( by user) and save the text how should we do it?